leveleditor.cmd

@ECHO OFF
:leveleditor.cmd [<"Integer": Level Selection> or <"OUT": Disable Terminal Support>]

IF NOT DEFINED VERCODE EXIT
IF NOT %1.==OUT. (
	PUSHD "../.."
	IF NOT %1.==. (
		SET SELECTED=%1
	)
)

:EDITOR
COLOR 0F
MODE CON:COLS=%COLS% LINES=%LINES%

IF NOT DEFINED SELECTED GOTO EXIT

START /MIN "RichManager" "%RichManager%" State=Level %SELECTED% - Chapter %CHAPTER%;Details=Editing a level;LargeImage=preview_battle;LargeImageTooltip=;SmallImage=icon;SmallImageTooltip=Battles of Batch

ECHO.҉  Preparing Your Amazing Battle
ECHO.  0%%
CALL "%SCRIPTS_GAME%\loader.cmd"

:DISPLAY
SET LOAD.ERR=
(
CLS
ECHO.[?25l.-------------------.-----------------------------------------------------------------------------------------------.
ECHO.^| Press %RGB.PINK%Q to return ^|^|
ECHO.^|-------------------'^|
FOR /L %%I IN (1, 1, 44) DO ECHO.^|^|
ECHO.'-------------------------------------------------------------------------------------------------------------------'
ECHO.%LOC.HP.P%
ECHO.     ___             
ECHO.    //_\\_          
ECHO.  ."\\    ".        
ECHO. /          \       
ECHO. ^|           \_     
ECHO. ^|       ,--.-.^)    
ECHO.  \     /  o \o\    
ECHO.  /\/\  \    /_/    
ECHO.   (_.   `--'__^)    
ECHO.    ^|     .-'  \    
ECHO.    ^|  .-'.     ^)   
ECHO.    ^| (  _/--.-'    
ECHO.    ^|  `.___.'      
ECHO.    ^|               

ECHO.^|                                                                                                                 ^|Your HP: %RGB.GREEN%%PLAYER.HP.NOW%%RGB.GRAY%/%PLAYER.HP.FULL% You dealt %PLAYER.ATTACK.AMOUNT% DMG to %PLAYER.ATTACK.ENEMY% - CRIT: %ATK.CRIT%Enemy Total HP: %ENEMY.HP.NOW.T%/%ENEMY.HP.FULL.T%
ECHO.Your AV: %RGB.PURPLE%%AV.PLAYER% ^(Your Turn^)           

ECHO.:---------: HELP - ^? :---------:
ECHO.:   %RGB.COIN%Select an enemy to edit:   :
ECHO.:    Navigate using %RGB.CYAN%I and %RGB.CYAN%K.   :
ECHO.:  Press %RGB.CYAN%C to create an enemy! :
ECHO.:------------------------------:
ECHO.         %RGB.AQUAMARINE%^> Edit Mode ^<         
ECHO.                                                          
ECHO.:------------------------------------:
ECHO.  %RGB.GREEN%Once done, press %RGB.CYAN%CTRL + %RGB.CYAN%S to save.
ECHO.:------------------------------------:

ECHO. .-----------: %RGB.PURPLE%GUIDE :-----------.
ECHO. Use I ^& K to %RGB.YELLOW%select an enemy.
ECHO. Use W A S ^& D to %RGB.YELLOW%move the enemy.
ECHO. Use J ^& L to %RGB.YELLOW%move an enemy left
ECHO. or right by just one character.
ECHO. Use C to %RGB.YELLOW%create a new enemy.
ECHO. Use E to %RGB.YELLOW%edit an enemy's %RGB.CYAN%data.
ECHO. Use CTRL + X to %RGB.RED%delete an enemy.
ECHO. Use R to %RGB.YELLOW%refresh the menu.
ECHO. Use CTRL + R to %RGB.YELLOW%undo all changes.
)

:: Calculate the HP of all enemies together
SET ENEMY.HP.NOW.T=
FOR /L %%I IN (1,1,%EN.MAX%) DO (
	SET /A ENEMY.HP.NOW.T+=ENEMY.HP.NOW.%%I
)

:RE

:: Display the HP bars
CALL "%SCRIPTS_GAME%\hpbar_now.cmd"
CALL :BATTLE-DISPLAY_CHOICE

%CHOICE%
IF %CHOICE.INPUT%.==. GOTO DISPLAY
IF /I "%CHOICE.INPUT%"=="K" (
	CALL :BATTLE-S_CHOICE
	CALL :BATTLE-DISPLAY_CHOICE
)
IF /I "%CHOICE.INPUT%"=="I" (
	CALL :BATTLE-W_CHOICE
	CALL :BATTLE-DISPLAY_CHOICE
)
IF /I "%CHOICE.INPUT%"=="J" (
	CALL :MOVE LEFT
)
IF /I "%CHOICE.INPUT%"=="L" (
	CALL :MOVE RIGHT
)
IF /I "%CHOICE.INPUT%"=="W" (
	CALL :MOVE UP
)
IF /I "%CHOICE.INPUT%"=="S" (
	CALL :MOVE DOWN
)
IF /I "%CHOICE.INPUT%"=="A" (
	CALL :MOVE LEFT +1
)
IF /I "%CHOICE.INPUT%"=="D" (
	CALL :MOVE RIGHT +1
)
IF /I "%CHOICE.INPUT%"=="C" (
	CALL :CREATE
	GOTO DISPLAY
)
IF /I "%CHOICE.INPUT%"=="E" (
	CALL :EDIT
	GOTO DISPLAY
)
IF /I "%CHOICE.INPUT%"=="" (
	CALL :DELETE
	GOTO DISPLAY
)
IF /I "%CHOICE.INPUT%"=="" (
	CALL :EXPORT
) ELSE ECHO.                                             

IF /I "%CHOICE.INPUT%"=="R" (
	MODE CON:COLS=%COLS% LINES=%LINES%
	GOTO DISPLAY
)
IF /I %CHOICE.INPUT%==TIMEOUT (MODE CON:COLS=%COLS% LINES=%LINES%&GOTO DISPLAY)
IF /I %CHOICE.INPUT%== (
	GOTO EDITOR
)
IF /I "%CHOICE.INPUT%"=="Q" (
	GOTO EXIT
)
GOTO RE

:EDIT
SET TMP.NAV=20
:EDIT-RE
SET LOAD.ERR=
COLOR 08
SETLOCAL ENABLEDELAYEDEXPANSION
ECHO.[?25l
ECHO.  .-------------------------.
ECHO.:-:                         :-:%RGB.CYAN%Type: %RGB.YELLOW%!ENEMY.TYPE.%INPUTATK%!
ECHO.  : -  -  -  -  -  -  -  -  :
ECHO.:-:                         :-:%RGB.CYAN%Level: %RGB.YELLOW%!ENEMY.LVL.%INPUTATK%!
ECHO.  '-------------------------'
ENDLOCAL
ECHO.
ECHO.%RGB.GRAY%[Use A to select]
ECHO.%RGB.GRAY%[Use W and S to navigate]
ECHO.%RGB.GRAY%[Press Q to return]
ECHO.[%TMP.NAV%;41H^>^<
%CHOICE%
IF %CHOICE.INPUT%.==. GOTO EDIT-RE
IF /I %CHOICE.INPUT%==Q EXIT /B 0
IF /I %CHOICE.INPUT%==CANCEL EXIT /B 0
IF /I %CHOICE.INPUT%==W IF NOT %TMP.NAV% LEQ 20 SET /A TMP.NAV-=2
IF /I %CHOICE.INPUT%==S IF NOT %TMP.NAV% GEQ 22 SET /A TMP.NAV+=2
IF /I NOT %CHOICE.INPUT%==A GOTO EDIT-RE
:EDIT-INPUT
SET /A "TMP.SELECTED=((%TMP.NAV% - 20) / 2) + 1"
SETLOCAL ENABLEDELAYEDEXPANSION
%INPUT% "PROMPT=[?25h" "length=8"
ENDLOCAL&SET UDERFINE=%UDERFINE: =_%
IF "%UDERFINE%"==")_" GOTO EDIT-INPUT
IF %TMP.SELECTED% EQU 1 (
	CALL SET TMP.OLDTYPE=%%ENEMY.TYPE.%INPUTATK%%%
	SET TMP.TYPE=%UDERFINE%
) ELSE (
	SET TMP.TYPE=%%ENEMY.TYPE.%INPUTATK%%%
)
IF %TMP.SELECTED% EQU 2 (
	SETLOCAL ENABLEDELAYEDEXPANSION
	ECHO %UDERFINE%| FINDSTR /R "^[1-9][0-9]*$">NUL
	IF ERRORLEVEL 1 (
		CALL "%DEV_ERR%" Error registering enemy:Level is not an integer.
		GOTO EDIT-RE
	)
	ENDLOCAL
	SET TMP.LVL=%UDERFINE%
) ELSE SET TMP.LVL=%%ENEMY.LVL.%INPUTATK%%%
for /l %%I in (1,1,7) do (
    SET "EN.%INPUTATK%.LINE.%%I="
)

:: Register the enemy
CALL "%ENEMY%" %TMP.TYPE% %INPUTATK% %TMP.LVL%
IF NOT DEFINED EN.%INPUTATK%.LINE.1 (
	:: If it doesn't exist, return.
	CALL "%DEV_ERR%" Error registering enemy:Invalid Enemy.
	CALL "%ENEMY%" %TMP.OLDTYPE% %INPUTATK% %TMP.LVL%
	GOTO EDIT-RE
)

IF DEFINED LOAD.ERR GOTO EDIT-RE

:: Setup for the enemy.
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /F "TOKENS=1-2 DELIMS=," %%A IN ("!ENEMY.HP.AMOUNT.%INPUTATK%!") DO (
	ENDLOCAL
	CALL :RAND %INPUTATK% %%A %%B
)
SET /A ENEMY.HP.FULL.%INPUTATK%=ENEMY.HP.NOW.%INPUTATK%
FOR /L %%X IN (90,-10,10) DO CALL :CREATE-HPBAR %INPUTATK% %%X %%ENEMY.HP.FULL.%INPUTATK%%%
COLOR 08
GOTO EDIT-RE

:DELETE
IF %EN.MAX% LEQ 1 EXIT /B 0
FOR /F "TOKENS=3DELIMS=." %%1 IN ('SET ENEMY.TYPE.') DO (
	CALL :FIX-INDETIFIERS %INPUTATK% %%1
)
SET "ENEMY.TYPE.%EN.MAX%="
SET ENEMY.HP.NOW.%EN.MAX%=
SET /A EN.MAX-=1
SET /A INPUTATK=1
EXIT /B 0
:FIX-INDETIFIERS
SET /A TMP.PREV_CNT=%2-1
IF NOT %2 GTR %1 EXIT /B 0
SETLOCAL ENABLEDELAYEDEXPANSION
SET TMP.TYPE=!ENEMY.TYPE.%2!
SET TMP.LVL=!ENEMY.LVL.%2!
ENDLOCAL&CALL "%ENEMY%" %TMP.TYPE% %TMP.PREV_CNT% %TMP.LVL%
SET /A ENEMY.HP.NOW.%TMP.PREV_CNT%=ENEMY.HP.NOW.%2
SET /A ENEMY.HP.FULL.%TMP.PREV_CNT%=ENEMY.HP.NOW.%TMP.PREV_CNT%
SET /A LOC.W%TMP.PREV_CNT%=LOC.W%2
SET /A LOC.H%TMP.PREV_CNT%=LOC.H%2
CALL :CREATE-LOCATION %TMP.PREV_CNT% %%LOC.W%2%% %%LOC.H%2%%
FOR /L %%X IN (90,-10,10) DO CALL :CREATE-HPBAR %EN.MAX% %%X %%ENEMY.HP.FULL.%EN.MAX%%%
EXIT /B 0

:CREATE
(
COLOR 08
ECHO.[?25l┏━━━━━━━━━━━━━━━━━━━┫%RGB.CYAN%INPUT┠━━━━━━━━━━━━━━━━━━━┓
ECHO.┃                                             ┃
ECHO.┃       What type should the enemy be^?        ┃
ECHO.┃        See %RGB.CYAN%enemy.cmd for reference.         ┃
ECHO.┃                                             ┃
ECHO.┠╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌┨
ECHO.┃               ^>             ^<               ┃
ECHO.┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
ECHO.%RGB.GRAY%[Enter Q or CANCEL to cancel]
)
SETLOCAL ENABLEDELAYEDEXPANSION
%INPUT% "PROMPT=[?25h" "length=8"
ENDLOCAL&SET TMP.TYPE=%UDERFINE: =_%
IF "%TMP.TYPE%"==")_" GOTO CREATE
IF /I %TMP.TYPE%==Q EXIT /B 0
IF /I %TMP.TYPE%==CANCEL EXIT /B 0

(
COLOR 08
ECHO.[?25l┏━━━━━━━━━━━━━━━━━━━┫%RGB.CYAN%INPUT┠━━━━━━━━━━━━━━━━━━━┓
ECHO.┃                                             ┃
ECHO.┃       What level should the enemy be^?       ┃
ECHO.┃        See %RGB.CYAN%enemy.cmd for reference.         ┃
ECHO.┃                                             ┃
ECHO.┠╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌╌┨
ECHO.┃                   ^>     ^<                   ┃
ECHO.┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
ECHO.%RGB.GRAY%[Enter Q or CANCEL to cancel]
)
SETLOCAL ENABLEDELAYEDEXPANSION
%INPUT% "PROMPT=[?25h" "length=3"
ENDLOCAL&SET TMP.LVL=%UDERFINE: =_%
IF "%TMP.LVL%"==")_" GOTO CREATE
IF /I %TMP.LVL%==Q EXIT /B 0
IF /I %TMP.LVL%==CANCEL EXIT /B 0

:: Register Enemy
SET /A EN.MAX+=1
SET "EN.%EN.MAX%.LINE.1=
SET "EN.%EN.MAX%.LINE.2=
SET "EN.%EN.MAX%.LINE.3=
SET "EN.%EN.MAX%.LINE.4=
SET "EN.%EN.MAX%.LINE.5=
SET "EN.%EN.MAX%.LINE.6=
SET "EN.%EN.MAX%.LINE.7=

CALL "%ENEMY%" %TMP.TYPE% %EN.MAX% %TMP.LVL%

IF NOT DEFINED EN.%EN.MAX%.LINE.1 (
	CALL "%DEV_ERR%" Error registering enemy:Invalid Enemy.
	SET LOAD.ERR=TRUE
)
IF DEFINED LOAD.ERR (
	SET "ENEMY.TYPE.%EN.MAX%="
	SET ENEMY.HP.NOW.%EN.MAX%=
	SET /A EN.MAX-=1
	EXIT /B 0
)

SET INPUTATK=%EN.MAX%
:: Data Setup
SET /A AV.%EN.MAX%=%EN.MAX%*10
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /F "TOKENS=1-2 DELIMS=," %%A IN ("!ENEMY.HP.AMOUNT.%EN.MAX%!") DO (
	ENDLOCAL
	CALL :RAND %EN.MAX% %%A %%B
)
SET /A ENEMY.HP.FULL.%EN.MAX%=ENEMY.HP.NOW.%EN.MAX%
SET /A ENEMY.HP.FULL.T+=%%2
SET LOC.W%EN.MAX%=55
SET LOC.H%EN.MAX%=20
CALL :CREATE-LOCATION %EN.MAX% %%LOC.W%EN.MAX%%% %%LOC.H%EN.MAX%%%
FOR /L %%X IN (90,-10,10) DO CALL :CREATE-HPBAR %EN.MAX% %%X %%ENEMY.HP.FULL.%EN.MAX%%%
EXIT /B 0

:MOVE
CALL :CLEAR_INFO_SELECTION

IF %1==LEFT (
	SET /A LOC.W%INPUTATK%-=1%2
)

IF %1==RIGHT (
	SET /A LOC.W%INPUTATK%+=1%2
	ECHO.%TMP.LOC_HP_OLD%            
)

IF %1==UP (
	SET /A LOC.H%INPUTATK%-=1%2
)

IF %1==DOWN (
	SET /A LOC.H%INPUTATK%+=1%2
)

SETLOCAL ENABLEDELAYEDEXPANSION
IF !LOC.H%INPUTATK%! LEQ 3 (
	ENDLOCAL
	CALL :MOVE-UNDO %1 %2
) ELSE IF !LOC.H%INPUTATK%! GEQ 40 (
	ENDLOCAL
	CALL :MOVE-UNDO %1 %2
) ELSE IF !LOC.W%INPUTATK%! LEQ 21 (
	ENDLOCAL
	CALL :MOVE-UNDO %1 %2
) ELSE IF !LOC.W%INPUTATK%! GEQ 94 (
	ENDLOCAL
	CALL :MOVE-UNDO %1 %2
) ELSE ENDLOCAL


CALL :CREATE-LOCATION %INPUTATK% %%LOC.W%INPUTATK%%% %%LOC.H%INPUTATK%%%

EXIT /B 0
:MOVE-UNDO
IF %1==LEFT (
	SET /A LOC.W%INPUTATK%+=1%2
)

IF %1==RIGHT (
	SET /A LOC.W%INPUTATK%-=1%2
)

IF %1==UP (
	SET /A LOC.H%INPUTATK%+=1%2
)

IF %1==DOWN (
	SET /A LOC.H%INPUTATK%-=1%2
)
EXIT /B 0

:CREATE-LOCATION
SET TMP=0
SET LOC.EN.%1=[%3;%2H
SET /A TMP=%2-1
SET MOV.EN.%1=[%TMP%C
SET /A TMP=%3-1
SET LOC.HP.%1=[%TMP%;%2H
EXIT /B 0

:EXPORT
SETLOCAL ENABLEDELAYEDEXPANSION
(
ECHO.IF NOT DEFINED VERCODE EXIT
ECHO.
ECHO.::REWARDS
ECHO.SET REWARD.MONEY=%REWARD.MONEY%
ECHO.SET REWARD.XP=%REWARD.XP%
ECHO.
ECHO.::ENEMIES
FOR /L %%I IN (1,1,%EN.MAX%) DO (
	ECHO.CALL "%%ENEMY%%" !ENEMY.TYPE.%%I! %%I !ENEMY.LVL.%%I!
)
ECHO.
ECHO.::DISPLAY
FOR /L %%I IN (1,1,%EN.MAX%) DO (
	ECHO.SET LOC.W%%I=!LOC.W%%I!
	ECHO.SET LOC.H%%I=!LOC.H%%I!
	ECHO.
)
ECHO.SET LOC.WP=%LOC.WP%
ECHO.SET LOC.HP=%LOC.HP%
ECHO.
ECHO.::LOOT TABLE
FOR /L %%I IN (1,1,%LOOT.MAX%) DO (
	ECHO.SET LOOT.%%I=!LOOT.%%I!
	ECHO.SET LOOT.%%I.X=!LOOT.%%I.X!
	ECHO.SET LOOT.%%I.SAV=!LOOT.%%I.SAV!
	ECHO.SET LOOT.%%I.ONCE=!LOOT.%%I.ONCE!
	ECHO.
)
ECHO.::END
ECHO.EXIT /B 0
)>"data\levels\lvl%SELECTED%\setup.cmd"
ECHO.%RGB.GREEN%√ %RGB.TRUE%Level has been exported at "lvl%SELECTED%\setup.cmd"
ENDLOCAL
EXIT /B 0

:BATTLE-S_CHOICE
SETLOCAL ENABLEDELAYEDEXPANSION
IF %INPUTATK% GTR %EN.MAX% (SET INPUTATK=1) ELSE SET /A INPUTATK+=1
:BATTLE-S_CHOICE-RE
IF !ENEMY.HP.NOW.%INPUTATK%! EQU 0 IF %INPUTATK% GTR %EN.MAX% (SET INPUTATK=1) ELSE (
	SET /A INPUTATK+=1
	GOTO BATTLE-S_CHOICE-RE
)
IF !ENEMY.HP.NOW.%INPUTATK%! EQU 0 GOTO :BATTLE-S_CHOICE-RE
ENDLOCAL&&SET INPUTATK=%INPUTATK%
EXIT /B 0
:BATTLE-W_CHOICE
SETLOCAL ENABLEDELAYEDEXPANSION
IF %INPUTATK% LSS 1 (SET INPUTATK=%EN.MAX%) ELSE SET /A INPUTATK-=1
:BATTLE-W_CHOICE-RE
IF !ENEMY.HP.NOW.%INPUTATK%! EQU 0 IF %INPUTATK% LSS 1 (
	SET INPUTATK=%EN.MAX%
) ELSE (
	SET /A INPUTATK-=1
	GOTO BATTLE-W_CHOICE-RE
)
IF !ENEMY.HP.NOW.%INPUTATK%! EQU 0 GOTO :BATTLE-W_CHOICE-RE
ENDLOCAL&&SET INPUTATK=%INPUTATK%
EXIT /B 0
:BATTLE-DISPLAY_CHOICE
SETLOCAL ENABLEDELAYEDEXPANSION
IF DEFINED TMP.LOC_HP_OLD (
	:: Clears the info that appear on the right side when focusing on an enemy.
	ECHO.!LOC.HP.%INPUTATK%!    !LOC.HP.%INPUTATK%!             !LOC.HP.%INPUTATK%!            %TMP.LOC_HP_OLD%    %TMP.LOC_HP_OLD%             %TMP.LOC_HP_OLD%             %TMP.LOC_HP_OLD%             %TMP.LOC_HP_OLD%             
)
SET TMP.LOC_HP_OLD=!LOC.HP.%INPUTATK%!
FOR /F "TOKENS=1-2 DELIMS=," %%A IN ("!ENEMY.ATK.AMOUNT.%INPUTATK%!") DO (
	SET /A "ENEMY.MAXP_ATK=%%A+%%B"
	SET /A "ENEMY.MINP_ATK=%%B"
)
ECHO.!LOC.HP.%INPUTATK%!^| ^>' ^>!LOC.HP.%INPUTATK%!%RGB.PURPLE%AV: !AV.%INPUTATK%!!LOC.HP.%INPUTATK%!%RGB%245;151;151mAtk: !ENEMY.MINP_ATK!~!ENEMY.MAXP_ATK!!LOC.HP.%INPUTATK%!%RGB%176;225;187mHP: !ENEMY.HP.NOW.%INPUTATK%!!LOC.HP.%INPUTATK%!%RGB.CYAN%Lvl: !ENEMY.LVL.%INPUTATK%!
ENDLOCAL&&SET TMP.LOC_HP_OLD=%TMP.LOC_HP_OLD%
EXIT /B 0

:CREATE-HPBAR
SET CNT1=%1&SET CNT2=%2&SET TMP_ENEMY.HP.FULL=%3
SET /A "ENEMY.HOLO.HP.%CNT1%.%CNT2%=%TMP_ENEMY.HP.FULL%00/100"&SET /A "ENEMY.HOLO.HP.%CNT1%.%CNT2%=ENEMY.HOLO.HP.%CNT1%.%CNT2%*(100-%CNT2%)"&SET /A "ENEMY.HOLO.HP.%CNT1%.%CNT2%=%TMP_ENEMY.HP.FULL%00-ENEMY.HOLO.HP.%CNT1%.%CNT2%"&SET /A "ENEMY.HOLO.HP.%CNT1%.%CNT2%=ENEMY.HOLO.HP.%CNT1%.%CNT2%/100"
EXIT /B 0

:RAND
SET /A "ENEMY.HP.NOW.%1=%random% %% %2 %3"
EXIT /B 0

:EXIT
IF NOT %1.==OUT. (
	POPD
	CLEAR
	ECHO ON
)
@EXIT /B 0