build.gradle

plugins {
	id 'java'
	id 'application'
	id 'org.javamodularity.moduleplugin' version '1.8.12'
	id 'org.openjfx.javafxplugin' version '0.0.13'
	id 'org.beryx.jlink' version '3.1.1'
}

group 'tech.anonymoushacker1279'
version '1.1.0'

apply from: 'optimization_utils.gradle'

def getGitHash = { ->
	def stdout = new ByteArrayOutputStream()
	exec {
		commandLine 'git', 'rev-parse', '--short', 'HEAD'
		standardOutput = stdout
	}
	return stdout.toString().trim()
}

java.toolchain.languageVersion = JavaLanguageVersion.of(23)

repositories {
	mavenLocal()
	mavenCentral()
	maven {
		url "https://maven.anonymoushacker1279.tech/releases"
	}
	maven {
		url "https://maven.anonymoushacker1279.tech/snapshots"
	}
}

tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

application {
	mainModule = 'tech.anonymoushacker1279.marshallcodeampinterface'
	mainClass = 'tech.anonymoushacker1279.marshallcodeampinterface.CODEInterfaceApplication'
}

javafx {
	version = '23.0.1'
	modules = ['javafx.controls', 'javafx.fxml', 'javafx.media']
}

dependencies {
	implementation 'org.jetbrains:annotations:26.0.1'
	implementation "tech.anonymoushacker1279:OrionBLE:1.0.0:all"
	implementation 'io.github.mkpaz:atlantafx-base:2.0.1'
	implementation 'org.apache.logging.log4j:log4j-core:2.24.3'
	implementation 'org.apache.commons:commons-math3:3.6.1'
	implementation 'org.semver4j:semver4j:5.5.0'
}

run {
	// Add RUNNING_IN_IDE environment variable to the run configuration
	environment 'RUNNING_IN_IDE', 'true'
}

tasks.named('processResources', ProcessResources).configure {
	LinkedHashMap<String, String> replaceProperties = [
			version: version, commit: getGitHash()
	]

	inputs.properties replaceProperties

	filesMatching(['**/app.properties']) {
		expand replaceProperties + [project: project]
	}
}

jlink {
	imageZip = project.file("${buildDir}/distributions/app-${javafx.platform.classifier}.zip")
	options = ['--strip-debug', '--compress', 'zip-9', '--no-header-files', '--no-man-pages']
	launcher {
		name = 'CODE Amp Interface'
	}

	forceMerge('annotations')
	forceMerge('OrionBLE')

	jpackage {
		targetPlatformName = 'win'
		if (targetPlatformName == 'win') {
			targetPlatform("win") {}
			installerType = 'msi'
		}
		installerOptions = [
				'--name', 'CODE Amp Interface',
				'--description', "A desktop program to modify amp settings without needing to use the Marshall Gateway app.",
				'--vendor', 'AnonymousHacker1279',
				'--copyright', 'Copyright (c) 2025 Nicholas Smit',
				'--about-url', 'https://github.com/AnonymousHacker1279/MarshallCodeAmpInterface',
				'--license-file', 'LICENSE'
		]
		if (installerType == 'msi') {
			imageOptions += ['--icon', 'src/main/resources/tech/anonymoushacker1279/marshallcodeampinterface/images/installer_icon.ico']
			installerOptions += [
					'--win-dir-chooser',
					'--win-menu',
					'--win-shortcut-prompt',
					'--win-help-url', 'https://github.com/AnonymousHacker1279/MarshallCodeAmpInterface'
			]
		}
	}
}

jlinkZip {
	group = 'distribution'
}