build.gradle

import org.gradle.nativeplatform.platform.internal.DefaultNativePlatform

plugins {
    id 'java'
    id 'application'
    id 'org.beryx.jlink' version '2.25.0'
}

sourceCompatibility = 17
targetCompatibility = 17

mainClassName = 'fr.fenrur.Main'

group 'fr.fenrur'
version '2.0'

application {
    mainModule = 'fr.fenrur'
    mainClass = 'fr.fenrur.Main'
}

jar {
    manifest {
        attributes 'Main-Class': 'fr.fenrur.Main'
    }
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

def currentOS = DefaultNativePlatform.currentOperatingSystem;
def platform
if (currentOS.isWindows()) {
    platform = 'win'
} else if (currentOS.isLinux()) {
    platform = 'linux'
} else if (currentOS.isMacOsX()) {
    platform = 'mac'
}

def javafxVersion = "19"

java {
    modularity.inferModulePath = true
}

dependencies {
    implementation ('org.jfxtras:jmetro:11.6.16') {
        exclude group: 'org.openjfx', module: 'javafx-base'
        exclude group: 'org.openjfx', module: 'javafx-controls'
        exclude group: 'org.openjfx', module: 'javafx-graphics'
        exclude group: 'org.openjfx', module: 'javafx-fxml'
    }
    implementation "org.openjfx:javafx-base:${javafxVersion}:${platform}"
    implementation "org.openjfx:javafx-controls:${javafxVersion}:${platform}"
    implementation "org.openjfx:javafx-graphics:${javafxVersion}:${platform}"
    implementation "org.openjfx:javafx-fxml:${javafxVersion}:${platform}"
    implementation 'com.github.Dansoftowner:jSystemThemeDetector:3.8'
}

jlink {
    application.mainModule = "fr.fenrur"
    options = ['--bind-services', '--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']

    launcher {
        name = 'Environment Variables'
        noConsole = true
    }
    jpackage {
        def currentOs = org.gradle.internal.os.OperatingSystem.current()
        def imgType = currentOs.macOsX ? 'icns' : 'png'
        icon = "icons/favicon.$imgType"
        installerOptions += [
                '--vendor', 'Fenrur',
                '--app-version', version
        ]
    }
}