build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.1' // 1.8.4 не юзается, т.к. он не работает нифига
    }
}

plugins {
    id 'java'
    id 'groovy'
    id 'maven'
}

group 'ru.rarescrap'
version '1.0.0'
archivesBaseName = "depATs"

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    compile gradleApi()
    testCompile group: 'junit', name: 'junit', version: '4.12'
    compile 'org.apache.commons:commons-lang3:3.9' // В основном для генерации equals()'ов
    testCompile 'nl.jqno.equalsverifier:equalsverifier:1.+' // Для удобного тестирования equals() и hashCode()
}

// Подготавливает maven-публикацию, которая будет использоваться в bintray
// Именно тут определяются артефакты для публикации
apply plugin: 'maven-publish'
publishing {
    publications {
        BintrayPublication(MavenPublication) {
            from components.java // Артефакты по умолчанию. Отлючаем их, т.к. нам нужно артефакт main-модуля заменить на артефакт от api-модуля
            artifact sourcesJar
            groupId group
            artifactId archivesBaseName
            version version
        }
    }
}

// Публикация либы в bintray/jcenter
apply plugin: 'com.jfrog.bintray'
bintray {
    user = 'rarescrap'
    key = System.getenv('BINTRAY_KEY')
    publications = ['BintrayPublication']
    pkg {
        repo = 'minecraft'
        name = 'DepATs'
        licenses = ['GPL-3.0']
        vcsUrl = 'https://github.com/RareScrap/DepATs.git'
        version {
            name = this.version
            released  = new Date()
        }
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

// Устраняет ошибки компиляции из-за русских комментов
tasks.withType(JavaCompile) { options.encoding = 'UTF-8' }