build.gradle

apply plugin: 'java'
apply plugin: 'maven'

version='1.0.1-SNAPSHOT'
group='com.simsilica'

ext.jmeVersion = "3.1.0-stable"

repositories {
    mavenLocal()

    if( JavaVersion.current() == JavaVersion.VERSION_1_7 ) {
        // Fallback for JDK 7 that can no longer connect to jcenter with https
        maven { url "http://jcenter.bintray.com" }
    } else {
        jcenter()
    }
}

// Make sure the build file declares what it actually imports
configurations.compile {
    transitive = false
}

// In this section you declare the dependencies for your production and test code
dependencies {
    compile "org.jmonkeyengine:jme3-core:$jmeVersion"
    compile 'org.slf4j:slf4j-api:1.7.13'
}


// Configuration to produce maven-repo style -sources and -javadoc jars
task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
    exclude '**/.backups'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}