build.gradle

// Настройки для всех проектов


import org.apache.tools.ant.filters.ReplaceTokens
import proguard.gradle.ProGuardTask

allprojects {

    apply plugin: 'java'
    repositories {
        mavenCentral()
        mavenLocal()
    }
    dependencies {
        compileOnly 'org.projectlombok:lombok:1.18.12'
        annotationProcessor 'org.projectlombok:lombok:1.18.12'

        testCompileOnly 'org.projectlombok:lombok:1.18.12'
        testAnnotationProcessor 'org.projectlombok:lombok:1.18.12'
        compileOnly 'org.jetbrains:annotations:16.0.2'
    }

    group = 'ru.spliterash'
    version = '3.0.6'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    processResources {
        from(sourceSets.main.resources.srcDirs) {
            filter ReplaceTokens, tokens: [version: version]
        }
    }

}

subprojects {
    jar {
        from {
            def projectClasses = configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
            def subProject = subprojects.collect { p ->
                p.jar.outputs.files.getFiles().collect {
                    it.isDirectory() ? it : zipTree(it)
                }
            }
            return projectClasses + subProject
        }.exclude('META-INF', 'META-INF/**')
    }
}

dependencies {
    compile project(":http:shared")
    compileOnly 'com.google.code.gson:gson:2.8.0'
}
String jarName = 'VkChat'
File jarFolder = file("$rootDir/jars/")
task createFatJar(type: Jar) {
    duplicatesStrategy(DuplicatesStrategy.EXCLUDE)
    dependsOn allprojects.build
    destinationDirectory = jarFolder
    archiveFileName = jarName + ".jar"
    from {
        return allprojects.collect { p ->
            p.jar.outputs.files.getFiles().collect {
                it.isDirectory() ? it : zipTree(it)
            }
        }
    }
    exclude('META-INF', 'META-INF/**')
    with jar
}
build {
    dependsOn ":http:jdk11:build"
    dependsOn ":http:jdk8:build"
}


//Следующий код идёт после инициализации сабмодулей
evaluationDependsOnChildren()


buildscript {
    repositories {
        flatDir dirs: "$System.env.PROGUARD_HOME/lib"

    }
    dependencies {
        classpath ':proguard:'
    }
}

List<File> getProGuardDependencies() {
    File libFolder = new File(rootProject.getProjectDir(), "libs")
    delete libFolder
    Set<ResolvedArtifact> compileOnly = new HashSet<>()
    Set<ResolvedArtifact> runTime = new HashSet<>()
    allprojects.each { pro ->
        pro.configurations.compileOnly.resolvedConfiguration.resolvedArtifacts.each {
            compileOnly.add(it)
        }
        pro.configurations.runtime.resolvedConfiguration.resolvedArtifacts.each {
            runTime.add(it)
        }
    }
    compileOnly.removeIf({ a ->
        if (a.id.componentIdentifier.displayName.contains("project :")) {
            return true
        } else {
            return runTime
                    .stream()
                    .anyMatch({ rA ->
                        a.name == rA.name
                    })
        }
    })
    return compileOnly.collect { a ->
        a.getFile()
    }
}

task copyDependencyes(type: Copy) {
    from(getProGuardDependencies()) into new File(rootDir, 'dependencies')
}


task proguard(type: ProGuardTask, dependsOn: createFatJar) {
    def libs = getProGuardDependencies()
    println(libs)
    configuration("conf.pro")
    libraryjars libs
    injars new File(jarFolder, jarName + ".jar")
    outjars new File(jarFolder, jarName + "-minifed.jar")
}