VCNL4200-ProxIntDemo.spin2

{
----------------------------------------------------------------------------------------------------
    Filename:       VCNL4200-ProxIntDemo.spin2
    Description:    Demo of the VCNL4200 driver
        * Proximity sensor interrupt functionality
    Author:         Jesse Burt
    Started:        Feb 10, 2021
    Updated:        Jun 6, 2024
    Copyright (c) 2024 - See end of file for terms of use.
----------------------------------------------------------------------------------------------------
}

' MikroE Click adapter board base pin
#define CLICK_BASE 16
#include "core.con.click.spin2"

CON

    _clkfreq    = cfg._clkfreq_def
    _xtlfreq    = cfg._xtlfreq

' -- User-defined constants
    LED         = cfg.LED1
    'INT_PIN     = 2                            ' comment out #include above to use
' --

    { IMPORTANT NOTE:
        Ensure you power the VCNL4200's IR LED from a high current 5V source (>800mA); powering it
        via some boards' 5V outputs isn't recommended. The high current draw can cause strange
        serial behavior and failure to load code to the Propeller.

        On the MikroE Click board (Parallax #64211), this is the 5V pin. }


OBJ

    cfg:    "boardcfg.p2eval"
    ser:    "com.serial.terminal.ansi" | SER_BAUD=2_000_000
    sensor: "sensor.light.vcnl4200" | SCL=SCL_PIN, SDA=SDA_PIN, I2C_FREQ=400_000

    { use this line instead to use custom I/O pins }
    'sensor: "sensor.light.vcnl4200" | SCL=0, SDA=1, I2C_FREQ=400_000

VAR

    long _isr_stack[50], _interrupt


PUB main()

    setup()

    sensor.preset_prox_long_range()               ' set to proximity sensor mode

    { clear interrupts, and set low and high thresholds }
    sensor.int_clear()
    sensor.prox_int_set_lo_thresh(100)
    sensor.prox_int_set_hi_thresh(200)
    { interrupt mask (bitwise OR '|' together if desired)
        INT_NEAR: trigger when proximity > prox_int_set_hi_thresh()
        INT_FAR: trigger when proximity < prox_int_set_lo_thresh()
    }
    sensor.prox_int_mask(sensor.INT_NEAR)
    ser.pos_xy(0, 3)
    ser.printf(@"Thresh  low: %d high: %d",    sensor.prox_int_lo_thresh(), ...
                                                sensor.prox_int_hi_thresh() )

    repeat
        ser.pos_xy(0, 5)
        ser.printf(@"Proximity ADC: %5.5d", sensor.prox_data())
        if ( _interrupt )
            ser.str(@"   INTERRUPT (press c to clear)")

        ser.clear_line()
        if ( ser.getchar_noblock() == "c" )
            sensor.int_clear()


PUB cog_isr()
' Interrupt service routine
    pinf(INT_PIN)
    pinl(LED)

    repeat
        repeat until ( pinr(INT_PIN) == 0 )     ' wait for interrupt (active low)
        pinh(LED)
        _interrupt := TRUE
        repeat until ( pinr(INT_PIN) == 1 )     ' wait for interrupt to clear
        pinl(LED)
        _interrupt := FALSE


PUB setup()

    ser.start()
    ser.clear()
    ser.strln(@"Serial terminal started")

    if ( sensor.start() )
        ser.strln(@"VCNL4200 driver started")
    else
        ser.strln(@"VCNL4200 driver failed to start - halting")
        repeat

    cogspin(NEWCOG, cog_isr(), @_isr_stack)     ' start the ISR in another cog


DAT
{
Copyright 2024 Jesse Burt

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
associated documentation files (the "Software"), to deal in the Software without restriction,
including without limitation the rights to use, copy, modify, merge, publish, distribute,
sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or
substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT
NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,
DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT
OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
}