build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
apply from: 'buildsystem/dependencies.gradle'

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.3+'
        classpath 'me.tatarka:gradle-retrolambda:3.2.0'
        classpath 'com.neenbedankt.gradle.plugins:android-apt:1.6'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        jcenter()
    }
    ext {
        androidApplicationId = 'com.misotest.flickrgalleryapp'
        androidVersionCode = 2
        androidVersionName = "0.0.2"
        minSdkVersion = 15
        targetSdkVersion = 22
        testInstrumentationRunner = "android.support.test.runner.AndroidJUnitRunner"

        //Android
        androidBuildToolsVersion = "22.0.1"
        androidCompileSdkVersion = 22

    }
}

task wrapper(type: Wrapper) {
    description 'Creates the gradle wrapper.'
    gradleVersion '2.5'
}

task runDomainUnitTests(dependsOn: [':domain:test']) {
    description 'Run unit tests for both domain and data layers.'
}

task runDataUnitTests(dependsOn: [':data:cleanTestDebug', ':data:testDebug']) {
    description 'Run unit tests for both domain and data layers.'
}

task runUnitTests(dependsOn: ['runDomainUnitTests', 'runDataUnitTests']) {
    description 'Run unit tests for both domain and data layers.'
}

task runAcceptanceTests(dependsOn: [':presentation:connectedAndroidTest']) {
    description 'Run application acceptance tests.'
}