-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathScrewCalculusPro.m
2839 lines (2067 loc) · 81.3 KB
/
ScrewCalculusPro.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(*
* ScrewCalculusPro.m - a Mathematica Package for Geometric and Kinematic
* Analysis of Robotic Systems
*
* Marco Gabiccini
*
* Dipartimento di Ingegneria Meccanica, Nucleare e della Produzione
* Facolt\[AGrave] di Ingegneria - Universit\[AGrave] di Pisa
* 56122 Pisa (PI) - Italy
*
* Copyright (c) 2007-2008, Marco Gabiccini
* Permission is granted to copy, modify and redistribute this file,
* provided that this header message is retained.
*
* Version 0.01
*
*)
Needs["NumericalCalculus`"];
(* BeginPackage["ScrewCalculusPro`", "Global`", "NumericalCalculus`"] *)
BeginPackage["ScrewCalculusPro`", "NumericalCalculus`"]
(*
* Preamble for Function Usage
*
* Document all of the functions which are defined in this file.
* Example: obtain documentation for function RotationQ just typing
* ?RotationQ
*
*)
(*
* Beginning of private section of the package
*)
(* Utility functions for manipulating matrices *)
AppendColumns::usage=
"AppendColumns[mat1, mat2, ...] gives a new matrix composed of the
submatrices mat1, mat2, ... , by joining their columns. The submatrices must
all have the same number of columns."
AppendRows::usage=
"AppendRows[mat1, mat2, ...] gives a new matrix composed of the submatrices
mat1, mat2, ..., by joining their rows. The submatrices must all have the same
number of rows."
StackCols::usage=
"StakCols[mat1, mat2, ...] gives a new matrix obtained by stacking the columns
of the submatrices mat1, mat2, ... . The submatrices must all have the same number
of rows."
StackRows::usage=
"StackRows[mat1, mat2, ...] gives a new matrix obtained by stacking the rows
of the submatrices mat1, mat2, ... . The submatrices must all have the same number
of columns."
BlockMatrix::usage=
"BlockMatrix[block] gives a matrix composed of a matrix of matrices."
BlockDiag::usage=
"BlockDiag[list] gives a block-diagonal matrix composed of the matrices listed in list."
TakeRows::usage=
"TakeRows[mat, part] takes the rows of matrix mat given by the partspec,
part. This uses the same notation as Take."
TakeColumns::usage=
"TakeColumns[mat, part] takes the columns of matrix mat given by the
partspec, part. This uses the same notation as Take."
TakeMatrix::usage=
"TakeMatrix[mat, start, end] gives the submatrix starting at position start
and ending at position end, where each position is expressed as a
{row, column} pair, e.g., {1, 2}."
SubMatrix::usage=
"SubMatrix[mat, start, dim] gives the submatrix of dimension dim = {m, n} starting
at position start = {i, j} in mat."
ZeroMatrix::usage=
"ZeroMatrix[n] gives the nxn zero matrix."
SelectionMatrix::usage=
"SelectionMatrix[q_List, indexlist_List] or SelectionMatrix[n_Integer, indexlist_List] returns the selection matrix with n=Length[q] columns that returns the
indexlist components of q."
SelectionMatrixColumns::usage=
"SelectionMatrixColumns[n, indexlist] returns the matrix that selects the indexlist columns from a matrix with n columns."
Magnitude::usage=
"Magnitude[v] gives length of v."
(* Utilities *)
RotX::usage=
"RotX[alpha] gives the rotation matrix about the X axis.";
RotY::usage=
"RotY[alpha] gives the rotation matrix about the Y axis.";
RotZ::usage=
"RotZ[alpha] gives the rotation matrix about the Z axis.";
ATan2::usage =
"ATan2[y, x] gives the angle with tangent given by y/x in the right quadrant."
EulZXZToMat::usage=
"EulZXZToMat[alpha, beta, gamma] returns the rotation matrix corresponding to the ZXZ Euler angles.
This is the one of the standard parametrizations employed in Multibody Dynamics."
EulZYZToMat::usage=
"EulZYZToMat[alpha, beta, gamma] returns the rotation matrix corresponding to the ZYZ Euler angles.
This is the one of the standard parametrizations employed in Robotics."
EulZYXToMat::usage = RPYToMat::usage=
"EulZYXToMat[alpha, beta, gamma] returns the rotation matrix corresponding to the ZYX Euler angles,
also known as Roll, Pitch and Yaw.
This is one of the standard parametrizations employed in Robotics."
RodriguezToMat::usage=
"RodriguezToMat[g1, g2, g3] returns the rotation matrix corresponding to the Rodriguez parameters g1, g2, g3.\
Recall that {g1, g2, g3} = r tan(theta/2)."
RodriguezToSpatialJac::usage=
"RodriguezToSpatialJac[g1, g2, g3] returns the Spatial Jacobian Js corresponding to Rodriguez parameters.\
This is such that w_s = Js dot{g1, g2, g3}, with w_s spatial components."
RodriguezToBodyJac::usage=
"RodriguezToBodyJac[g1, g2, g3] returns the Body Jacobian Jb corresponding to Rodriguez parameters.\
This is such that w_b = Jb dot{g1, g2, g3}, with w_b body fixed components."
EulZXZToSpatialJac::usage=
"EulZXZToSpatialJac[alpha, beta, gamma] returns the Spatial Jacobian Js corresponding to the ZXZ Euler angles.
This is such that w_s = Js dot{alpha, beta, gamma}, with w_s spatial components."
EulZXZToBodyJac::usage=
"EulZXZToBodyJac[alpha, beta, gamma] returns the Body Jacobian Jb corresponding to the ZXZ Euler angles.
This is such that w_b = Jb dot{alpha, beta, gamma}, with w_b body fixed components."
EulZYZToSpatialJac::usage=
"EulZYZToSpatialJac[alpha, beta, gamma] returns the Spatial Jacobian Js corresponding to the ZYZ Euler angles.
This is such that w_s = Js dot{alpha, beta, gamma}, with w_s spatial components."
EulZYZToBodyJac::usage=
"EulZYZToBodyJac[alpha, beta, gamma] returns the Body Jacobian Jb corresponding to the ZYZ Euler angles.
This is such that w_b = Jb dot{alpha, beta, gamma}, with w_b body fixed components."
EulZYXToSpatialJac::usage=
"EulZYXToSpatialJac[alpha, beta, gamma] returns the Spatial Jacobian Js corresponding to the ZYX Euler angles.
This is such that w_s = Js dot{alpha, beta, gamma}, with w_s spatial components."
EulZYXToBodyJac::usage=
"EulZYXToBodyJac[alpha, beta, gamma] returns the Body Jacobian Jb corresponding to the ZYX Euler angles.
This is such that w_b = Jb dot{alpha, beta, gamma}, with w_b body fixed components."
QuatToSpatialJac::usage=
"QuatToSpatialJac[q] returns the Spatial Jacobian Js corresponding to the unit quaternion q (1-vector).
If q = (q0, q1, q2, q3), w_s = Js dot{q}."
QuatToBodyJac::usage=
"QuatToBodyJac[q] returns the Body Jacobian Jb corresponding to the unit quaternion q (1-vector).
If q = (q0, q1, q2, q3), w_b = Jb dot{q}."
(* Inverse functions given only for ZYZ and RPY - both non singular and singular cases can be handled *)
MatToEulZYZ::usage=
"MatToEulZYZ[R] returns the Euler angles for the parametrization ZYZ corresponding to the rotation matrix R."
MatToEulZYX::usage=MatToRPY::usage=
"MatToEulZYX[R] returns the Euler angles for the parametrization ZYX (also called RPY) corresponding to the rotation matrix R."
MatToVect::usage=
"MatToVect[R] returns the orientation error e_O = r sin(theta), where r and theta are the components of the axis angle parametrization.
e_O represents also the axis form of the skew-symm matrix R_SS = (1/2) (R - R^T)."
FramesToVect::usage=
"FramesTovect[{ R, Rd }] returns the orientation error e_O = r sin(theta) of frame Rd (desired) w.r.t. R (actual) in the spatial frame\
where both R and Rd are expressed."
dexpInv::usage=
"dexpInv[w] gives the inverse of the exponential mapping to SO(3) of w."
(* Utilities for testing matrix properties *)
RotationQ::usage=
"RotationQ[m] tests whether matrix m is a rotation matrix.";
skewQ::usage=
"skewQ[m] tests whether matrix m is a skew-symmetrix matrix.";
(* Homogeneous representation *)
HomogeneousToVector::usage=
"HomogeneousToVector[q] extracts the cartesian coordinates from homogeneous components q.";
PointToHomogeneous::usage=
"PointToHomogeneous[q] gives the homogeneous representation of a point.";
VectorToHomogeneous::usage=
"VectorToHomogeneous[q] gives the homogeneous representation of a vector.";
RPToHomogeneous::usage=
"RPToHomogeneous[R,p] forms homogeneous matrix from rotation matrix R \
and position vector p.";
RigidOrientation::usage=
"RigidOrientation[g] extracts rotation matrix R from g.";
RigidPosition::usage=
"RigidPosition[g] extracts position vector p from g.";
RigidInverse::usage=
"RigidInverse[g] gives the inverse transformation of g";
RotationAxis::usage=
"RotationAxis[R] returns the rotation axis of R in SO(3)."
RotationParam::usage=
"RotationParam[R] returns the rotation axis the and amount of rotation of R in SO(3)."
(* Operations on so(3), the Lie algebra of SO(3) *)
AxisToSkew::usage=Skew::usage=Hat::usage=
"AxisToSkew[w] generates skew-symmetric matrix given 3 vector w";
SkewToAxis::usage=UnSkew::usage=HatInv::usage=
"SkewToAxis[S] extracts vector w from skew-symmetric matrix S";
SkewExp::usage=
"SkewExp[w,(theta)] gives the matrix exponential of an axis w.
Default value of Theta is 1.";
xitow::usage=
"xitow[xi] gives the angular part of twist xi."
xitov::usage=
"xitov[xi] gives the translational part of twist xi."
(* Operations on se(e), the Lie algebra of SE(3) *)
TwistExp::usage=
"TwistExp[xi,(Theta)] gives the matrix exponential of a twist xi.
Default value of Theta is 1.";
TwistToHomogeneous::usage=
"TwistToHomogeneous[xi] converts xi from a 6 vector to a 4x4 matrix.";
HomogeneousToTwist::usage=
"HomogeneousToTwist[xi] converts xi from a 4x4 matrix to a 6 vector.";
RigidTwist::usage=
"RigidTwist[g] extracts 6 vector xi from g and the angle theta that generates g.";
TwistPitch::usage=
"TwistPitch[xi] gives pitch of screw corresponding to a twist.";
TwistAxis::usage=
"TwistAxis[xi] gives axis of screw corresponding to a twist as q (point on axis), w (axis)";
TwistMagnitude::usage=
"TwistMagnitude[xi] gives magnitude of screw corresponding to a twist.";
ScrewToTwist::usage=
"ScrewToTwist[h, q, w] builds a twist from its screw coordinates h (pitch), q (point on axis), w (axis).";
(* Adjoint matrix calculations *)
RigidAdjoint::usage=
"RigidAdjoint[g] gives the adjoint matrix corresponding to g";
InverseRigidAdjoint::usage=
"InverseRigidAdjoint[g] gives the inverse adjoint matrix corresponding to g";
(* Operations on SO(n), the Lie group of rotation matrices *)
LocalTranTwist::usage =
"LocalTranTwist[gStart, gEnd] returns the twist and theta such that: gStart.TwistExp[xi,theta] = gEnd.
The xi coordinate are expressed in the local (gStart) reference frame."
GlobalTranTwist::usage =
"GlobalTranTwist[gStart, gEnd] returns the twist and theta such that: TwistExp[xi,theta].gStart = gEnd.
The xi coordinate are expressed in the global (identity) reference frame."
(* Unit quaternion < - > SO(3) matrices conversion utilities *)
QuatProd::usage=
"QuatProd[q1, q2] returns the composition product between two quaternions."
QuatInv::usage=
"QuatInv[q] returns the conjugate (also the inverse) of a unit quaternion."
QuatToMat::usage=
"QuatToMat[q] returns the rotation matrix associates with the unit quaternion q."
MatToQuat::usage=
"MatToQuat[R] returns the unit quaternion associated with the rotation matrix R."
QuatVectPart::usage=
"QuatVectorPart[R] returns the 3-vector part q of quaternion (q0, q) associated with the rotation matrix R."
MakeQuat::usage=
"MakeQuat[axis, angle] creates the unit quaternion given the unit vector of the axis and the angle."
MakeRot::usage=
"MakeRot[axis, angle] creates the rotation matrix given the unit vector of the axis and the angle."
QQTo4DRot::usage=
"QQTo4DRot[q1, q2] returns the 4D rotation matrix from two unit quaternions."
Lerp::usage=
"Lerp[qStart, qEnd, t] returns the Linear intERPolation function bewteen the unit quaternions qStart and qEnd.
Lerp[qStart, qEnd, t=0] = qStart and Lerp[qStart, qEnd, t=1] = qEnd."
Slerp::usage=
"Slerp[qStart, qEnd, t] returns the Spherical Linear intERPolation function bewteen the unit quaternions qStart and qEnd.
Slerp[qStart, qEnd, t=0] = qStart and Slerp[qStart, qEnd, t=1] = qEnd."
CRspline::usage=
"CRspline[q1, q2, q3, q4, t] returns the spline functions given the 4 unit quaternions q1, ..., q4. "
BZspline::usage=
"BZspline[q1, q2, q3, q4, t] returns the Bezier spline functions given the 4 unit quaternions q1, ..., q4. "
UBspline::usage=
"UBspline[q1, q2, q3, q4, t] returns the UB spline functions given the 4 unit quaternions q1, ..., q4. "
SCRspline::usage=
"SCRspline[q1, q2, q3, q4, t] returns the SCR spline functions given the 4 unit quaternions q1, ..., q4. "
SBZspline::usage=
"SBZspline[q1, q2, q3, q4, t] returns the SBZ spline functions given the 4 unit quaternions q1, ..., q4. "
SUBspline::usage=
"SUBspline[q1, q2, q3, q4, t] returns the SUB spline functions given the 4 unit quaternions q1, ..., q4. "
(*
* Systematic method to build forward kinematics and Spatial/Body Jacobians
*)
RevoluteTwist::usage=
"RevoluteTwist[q,w] builds the 6-vector corresponding to point q on the axis with unit vector w for a revolute joint.";
PrismaticTwist::usage=
"RevoluteTwist[q,w] builds the 6-vector corresponding to point q on the axis with unit vector w for a prismatic joint.";
ForwardKinematics::usage=
"ForwardKinematics[{xi1,th1}, ... ,{xiN,thN}, g0] computes the forward kinematics via the product of exponentials formula.
g0 is the initial affine tranformation if any.";
SpatialJacobian::usage=
"SpatialJacobian[{xi1,th1}, ... ,{xiN, thN} ,g0] computes the Spatial manipulator Jacobian of a robot defined by the given twists.";
BodyJacobian::usage=
"BodyJacobian[{xi1,th1}, ..., {xiN, thN}, g0] computes the Body manipulator Jacobian of a robot defined by the given twists.";
InertiaToCoriolis::usage=
"InertiaToCoriolis[B(q), q, q_dot] computes the Coriolis matrix given the inertia matrix, B, and a list of the joint variables, q,
and the list of joint variable derivatives, q_dot."
InertiaToCoriolisNotChristoffel::usage=
"InertiaToCoriolis[B(q), q, q_dot] computes the Coriolis matrix given the inertia matrix, B, and a list of the joint variables, q,
and the list of joint variable derivatives, q_dot."
(* Definitions for Denavit-Hartenberg convention *)
HomogeneousRotX::usage=
"HomogeneousRotX[alpha] computes the homogeneous version of a rotation of alpha about the X-axis."
HomogeneousRotY::usage=
"HomogeneousRotY[alpha] computes the homogeneous version of a rotation of alpha about the Y-axis."
HomogeneousRotZ::usage=
"HomogeneousRotZ[alpha] computes the homogeneous version of a rotation of alpha about the Z-axis."
HomogeneousTranslX::usage=
"HomogeneousTranslX[d] computes the homogeneous version of a translation of d along the X-axis."
HomogeneousTranslY::usage=
"HomogeneousTranslY[d] computes the homogeneous version of a translation of d along the Y-axis."
HomogeneousTranslZ::usage=
"HomogeneousTranslZ[d] computes the homogeneous version of a translation of d along the Z-axis."
DH::usage=
"DH[pars] computes the DH homogeneous matrix relative to the parameter list pars (row of DH table)."
DHFKine::usage=
"DHFKine[DHtable, j] computes the forward kinematics homogeneous matrix for the supplied DH table DHtable till j-th joint.\n
If j is omitted the complete forward kinematics (till the end effector) is returned.\n
Each DHtable row must have a string R or P in the last component to indicate the joint type.\n
DHFKine[DHtable, {Tb0, Tne}] computes the forward kinematics considering also the Tb0 (base-to-zero) and the
Tne (n-to-e.e.) homogeneous transformations."
DHJacob0::usage=
"DHJAcob0[DHtable] computes the DH spatial Jacobian for the supplied DH table DHtable."
DHJacobBase::usage=
"DHJacobBase[DHtable, Tb0] computes the DH spatial Jacobian for the supplied DH table DHtable, w.r.t. a base frame Sb (both origin and orientation are considered) \n\
where the displacement from Sb to S0 is expressed by the homogeneous matrix Tb0."
DHJacob0Dyn::usage=
"DHJacob0Dyn[DHtable, j] computes the DH spatial Jacobian till j-th joint with the needed empty columns stacked on the right."
DHJacobBaseDyn::usage=
"DHJacobBaseDyn[DHtable, {Tb0, Tne}, j] computes the DH spatial Jacobian till j-th joint with the needed empty columns stacked on the right\n\
considering also the initial offset 'Tb0' and final offset 'Tne'."
CGJacob0Dyn::usage=
"CGJacob0Dyn[DHtable, CGtable, j] computes the CG (linear velocity of the CG) spatial Jacobian till j-th joint with the needed empty columns stacked on the right.\n
Besides the DH table DHtable, a table with the pici (CGtable) must be supplied."
CGJacobBaseDyn::usage=
"CGJacobBaseDyn[DHtable, CGtable, {Tb0, Tne} j] computes the CG (linear velocity of the CG) spatial Jacobian till j-th joint with the needed empty columns stacked on the right.\n
Besides the DH table DHtable, a table with the pici (CGtable) and the homogeneous matrices {Tb0, Tne} initial [B to S0] and final [Sn to E] offset transformations must be supplied."
TensorDerivative::usage=
"TensorDerivative[J, q] computes the derivative of (nxn) matrix J w.r.t. vector q."
Regressor::usage=
"Regressor[DHtable, q, qp, v, vp, t, g0, k] directly computes the regressor for the supplied: DHtable, q (config.), qp (velocity), v (reference velocity), vp (reference acceleration), t (independent var),
g0 (components of gravity in {0}), k (contribute for the k-th link). If k is omitted the complete regressor is returned."
Inertia::usage=
"Inertia[DHtable, CGtable_, Masslist, Tensortable] returns matrix B(q) for the supplied: DHtable (DH table), GCtable (pici table), Masslist (list of link masses),
Tensortable (table with link inertia tensors)."
InertiaBase::usage=
"InertiaBase[DHtable, CGtable, Masslist, Tensortable, {Tb0, Tne}] returns matrix B(q) for the supplied: DHtable (DH table), GCtable (pici table), Masslist (list of link masses),
Tensortable (table with link inertia tensors), {Tb0, Tne} (initial [B to S0] and final [Sn to E] offset transformations)."
InertiaToCoriolis::usage=
"InertiaToCoriolis[B(q), q, qp] computes the Coriolis matrix given: the inertia matrix B, the joint variables q,
joint variable derivatives qp."
InertiaToCoriolisSlotineLi::usage=
"InertiaToCoriolisSlotineLi[B(q), q, qp] computes the Coriolis matrix given: the inertia matrix B, the joint variables q,
joint variable derivatives qp."
Gravitational::usage=
"Gravitational[DHtable, CGtable, Masslist, g0] computes the gravitational vector for the supplied: DHtable (DH table), GCtable (pici table), Masslist (list of link masses),
g0 (componenents of gravity in {0})."
GravitationalBase::usage=
"GravitationalBase[DHtable, CGtable, Masslist, gb, {Tb0, Tne}] computes the gravitational vector for the supplied: DHtable (DH table), GCtable (pici table), Masslist (list of link masses),
gb (componenents of gravity in {B}), {Tb0, Tne} (initial [B to S0] and final [Sn to E] offset transformations)."
DynamicEquations::usage=
"DynamicEquations[DHtable, CGtable, Masslist, Tensortable, g0, q, qp, v, vp] computes the LHS B(q)vp + C(q,qp)v + G(q) for the supplied:
DHtable (DH table), GCtable (pici table), Masslist (list of link masses), Tensortable (table with link inertia tensors), g0 (componenents of gravity in {0}),
q (config.), qp (velocity), v (Slotine-Li velocity), vp (Slotine-Li acceleration).\n
For the classical version simply set: v ->qp , vp -> qpp."
DynamicEquationsBase::usage=
"DynamicEquations[DHtable, CGtable, Masslist, Tensortable, gb, q, qp, v, vp, {Tb0, Tne}] computes the LHS B(q)vp + C(q,qp)v + G(q) for the supplied:
DHtable (DH table), GCtable (pici table), Masslist (list of link masses), Tensortable (table with link inertia tensors), gb (componenents of gravity in {B}),
q (config.), qp (velocity), v (Slotine-Li velocity), vp (Slotine-Li acceleration), {Tb0, Tne} (initial [B to S0] and final [Sn to E] offset transformations). \n
For the classical version simply set: v ->qp , vp -> qpp."
ExtractParameters::usage=
"ExtractParameters[CGtable, Masslist, Tensortable] returns a list with the inertia parameters reshaped according to the regressor formulation for the supplied:
GCtable (pici table), Masslist (list of link masses), Tensortable (table with link inertia tensors)."
SwitchAt::usage=
"Internal utility function."
NDMatrix::usage=
"NDMatrix[] returns the numerical derivative of the given matrix."
NullBasis::usage=
"NullBasis[A, indexlist] returns a matrix whose columns span the NullSpace of the input matrix A. The controls are the indexlist components of q_dot."
NullBasisNumerical::usage=
"NullBasisNumerical[A, q0, indexlist] returns a matrix whose columns span the NullSpace of the input matrix A. The controls are the indexlist components of q_dot."
Eye::usage=
"Eye[n] is equivalent to IdentityMatrix[n]."
(* constraint definitions *)
GraspMatrix::usage=
"GraspMatrix[EP] returns the grasp matrix G for a change of reference point expressed by vector EP.\nBeware that EP are the components of the vector EP in a fixed reference frame, not in the local E.E. frame."
GlobalGraspMatrix::usage=
"GlobalGraspMatrix[EPlist] returns the global grasp matrix G for the changes of reference point expressed by the vector list EPlist.\n\
Beware that the EPi's are the components of the vector EP in a fixed reference frame."
ConstraintMatrix::usage=
"ConstraintMatrix[type, axis, Rbe] returns the contraint matrix associated with the constraint type, its axis (if applicable) and Sb to Se transformation Rbe. Allowed contraint types are:\n\
'S' for Spherical joint, 'R' for Revolute joint, 'P' for prismatic joint, 'C' for clamped, 'PC' for Point Contact, 'PCWF' for Point Contact With Friction,'SF' for Soft Finger. \n\
Axis is taken into account only in 'R' and 'P' joint types. \n\
Rbe is always taken into account."
GlobalConstraintMatrix::usage=
"GlobalConstraintMatrix[{ {type1, axis1, Rbe1}, {type2, axis2, Rbe2}, ... }] returns the global constraint matrix for the supplied list.
The structure of each element must follow the structure of ConstraintMatrix."
FreeHandJacobian::usage=
"FreeHandJacobian[{ {DHtable1, var1, gb01}, {DHtable2, var2, gb02}, ... }] returns the global free hand Jacobian. This is the block-diag Jacobians for all the
fingers, where each one is described through its DH table, its joint variables and its initial pose w.r.t. to the base frame."
HandJacobian::usage=
"HandJacobian[fingerlist, constraintlist] returns the H.J matrix given 'fingerlist' as in FreeHandJacobian and 'constraintlist' as in GlobalConstraintMatrix. "
ObjectJac::usage=
"ObjectJac[function, pars] return the 6x6 object jacobian corresponding to the parametrization 'function' applied to parameters 'pars'."
CouplerJacobian::usage=
"CouplerJacobian[function, pars, constraintlist, pointlist] returns..."
PfaffianMatrix::usage=
"PfaffianMatrix[fingerlist, fstring, pars, constraintlist, pointlist] returns..."
(* graphical primitives *)
CreateGround::usage=
"CreateGround[{xmin, xmax, dx}, {ymin, ymax, dy}, colorplane, colorframe] creates the ground plane and the ground frame."
CreateFrame::usage=
"CreateFrame[g, color] returns a frame primitive associated with homogeneous transformation g."
CreateJoint::usage=
"CreateJoint[g, {height, radius}] creates a joint primitive."
CreateLink::usage=
"CreateLink[g, {length, radius}] creates a link primitive."
CreateRobot::usage=
"CreateRobot[]..."
BBox::usage=
"BBox[a, b, c]..."
EEllipsoid::usage=
"EEllipsoid[a, b, c]..."
CreateObject::usage=
"CreateObject[]..."
FindRedundantAnglesFromOrigin::usage=
"FindRedundantAnglesFromOrigin[]..."
(*
* Error messages
*
* Use the Mma error message facility so that we can turn off error
* messages that we don't want to hear about
*
*)
AxisToSkew::wrongD = "`1 argument` is not a 3 vector.";
SkewToAxis::notskewsymmetric = "`1 argument` is not a skew symmetric matrix";
Screws::wrongDimensions = "`1 argument`: Dimensions of input matrices incorrect.";
Screws::notSquare = "`1 argument`: Input matrix is not square.";
Screws::notVector = "`1 argument`: Input is not a vector.";
Begin["`Private`"]
(* PRECISION = Infinity; *)
(* PRECISION = 16; *)
(*
* Utility functions for stacking rows, columns, plus other matrix operations
*)
(* test for dimensions and matrix properties *)
SameColumnSize[l_List] := (SameQ @@ (Dimensions[#][[2]]& /@ l) )
SameRowSize[l_List] := (SameQ @@ (Dimensions[#][[1]]& /@ l) )
RotationQ[mat_] :=
Module[
{nr, nc, zmat},
(* First check to make sure that this is square matrix *)
If[Not[MatrixQ[mat]] || ({nr, nc} = Dimensions[mat]; nr != nc),
Message[Screws::notSquare];
Return[False]];
(* Check to see if R^T R = Identity *)
zmat = Simplify[mat . Transpose[mat]] - IdentityMatrix[nr];
Return[ And @@ Map[TrueQ[Simplify[#] == 0]&, Flatten[zmat]]]
];
skewQ[mat_] :=
Module[
{nr, nc, zmat},
(* First check to make sure that this is square matrix *)
If[Not[MatrixQ[mat]] || ({nr, nc} = Dimensions[mat]; nr != nc),
Message[Screws::notSquare];
Return[False]];
(* Check to see if A = -A^T *)
zmat = mat + Transpose[mat];
Return[ And @@ Map[TrueQ[Simplify[#] == 0]&, Flatten[zmat]]]
];
(* creation by appending, joining, blocking *)
AppendColumns[l__?MatrixQ] := Join[l] /; SameColumnSize[{l}]
AppendRows[l__?MatrixQ] := MapThread[Join, {l}] /;
SameRowSize[{l}]
StackCols[l__?MatrixQ] := AppendRows[l];
StackRows[l__?MatrixQ] := AppendColumns[l];
BlockMatrix[block_] :=
AppendColumns @@ Apply[AppendRows, block, {1}];
BlockDiag[list_] :=
Module[{r, mlist, nlist, m, n, i},
r = Length[list];
mlist = Dimensions[#][[1]]& /@ list;
nlist = Dimensions[#][[2]]& /@ list;
m = Plus @@ mlist;
n = Plus @@ nlist;
res = ZeroMatrix[m, n];
res[[ 1;;mlist[[1]], 1;;nlist[[1]] ]]= list[[1]];
For[ i=2, i <= r, ++i,
res[[ Plus@@Take[mlist, i-1]+1 ;; Plus@@Take[mlist, i], Plus@@Take[nlist, i-1]+1 ;; Plus@@Take[nlist, i] ]] = list[[i]]
];
Return[res];
];
(* extraction *)
TakeRows[mat_?MatrixQ, part_] := Take[mat, part]
TakeColumns[mat_?MatrixQ, part_] := Take[mat, All, part]
TakeMatrix[mat_?MatrixQ, start:{startR_Integer, startC_Integer},
end:{endR_Integer, endC_Integer}] :=
Take[mat, {startR, endR}, {startC, endC}] /;
And @@ Thread[Dimensions[mat] >= start] &&
And @@ Thread[Dimensions[mat] >= end]
SubMatrix[mat_List, start:{_Integer, _Integer}, dim:{_Integer,_Integer}] :=
TakeMatrix[mat, start, start+dim-1];
(* basic matrices *)
ZeroMatrix[0, ___] := {};
ZeroMatrix[m_Integer, 0] := Table[{}, {m}];
ZeroMatrix[m_Integer,n_Integer] :=
Normal[SparseArray[{},{m, n}]] /; m >= 0 && n>=0
ZeroMatrix[m_Integer] := ZeroMatrix[m, m] /; m >= 0
SelectionMatrix[q_List, indexlist_List] :=
Module[{m, eye},
m = Length[q];
eye = IdentityMatrix[m];
res = eye[[indexlist]];
Return[res];
];
SelectionMatrix[m_Integer, indexlist_List] :=
Module[{eye},
eye = IdentityMatrix[m];
res = eye[[indexlist]];
Return[res];
];
SelectionMatrixColumns[n_Integer, indexlist_List] :=
Module[{eye},
eye = IdentityMatrix[n];
res = Transpose[ eye[[indexlist]] ];
Return[res];
];
Magnitude[v_] :=
Module[
{},
If[Not[VectorQ[v]],
Message[Screws::wrongDimensions, "Vector"];
Return[Null];
];
Sqrt[v.v]
];
(* Utilities *)
(* Rotations about a single axis*)
RotX[alpha_] :=
Module[ {ca = Cos[alpha], sa = Sin[alpha]},
{{1, 0, 0},
{0, ca, -sa},
{0, sa, ca}
}
];
RotY[alpha_] :=
Module[ {ca = Cos[alpha], sa = Sin[alpha]},
{{ca, 0, sa},
{0, 1, 0},
{-sa, 0, ca}
}
];
RotZ[alpha_] :=
Module[ {ca = Cos[alpha], sa = Sin[alpha]},
{{ca, -sa, 0},
{sa, ca, 0},
{0, 0, 1}
}
];
ATan2[y_, x_] := ArcTan[x,y];
(* Parametrizations of SO(3) - Forward Map *)
EulZXZToMat[alpha_, beta_, gamma_]:=
Module[ {},
RotZ[alpha].RotX[beta].RotZ[gamma]
];
EulZYZToMat[alpha_, beta_, gamma_]:=
Module[ {},
RotZ[alpha].RotY[beta].RotZ[gamma]
];
EulZYXToMat[alpha_, beta_, gamma_]:=
Module[ {},
RotZ[alpha].RotY[beta].RotX[gamma]
];
RPYToMat[alpha_, beta_, gamma_]:= EulZYXToMat[alpha, beta, gamma];
(* Rodriguez parameters gamma = r tan(theta/2) *)
RodriguezToMat[gamma1_, gamma2_, gamma3_] :=
Module[ {gamma, hatgamma, modulusgammasquared},
gamma = {gamma1, gamma2, gamma3};
hatgamma = Hat[gamma];
modulusgammasquared = gamma.gamma;
IdentityMatrix[3] + 2/(1 + modulusgammasquared) (hatgamma + hatgamma.hatgamma)
];
RodriguezToSpatialJac[gamma1_, gamma2_, gamma3_] :=
Module[ {gamma, modulusgammasquared},
gamma = {gamma1, gamma2, gamma3};
modulusgammasquared = gamma.gamma;
2/(1 + modulusgammasquared) { { 1, -gamma3, gamma2},
{ gamma3, 1, -gamma1},
{-gamma2, gamma1, 1}
}
];
RodriguezToBodyJac[gamma1_, gamma2_, gamma3_] :=
Module[ {gamma, modulusgammasquared},
gamma = {gamma1, gamma2, gamma3};
modulusgammasquared = gamma.gamma;
2/(1 + modulusgammasquared) { { 1, gamma3, -gamma2},
{ -gamma3, 1, gamma1},
{ gamma2, -gamma1, 1}
}
];
(*
* Spatial and Body Jacobians relating Spatial or Body fixed angular velocity components to
* angle derivatives in various parametrizations
*)
EulZXZToSpatialJac[phi_, theta_, psi_]:=
Module[{},
{{ 0, Cos[phi], Sin[phi] Sin[theta] },
{ 0, Sin[phi], -Cos[phi] Sin[theta] },
{ 1, 0, Cos[theta] }
}
];
EulZXZToBodyJac[phi_, theta_, psi_]:=
Module[{},
{{ Sin[theta] Sin[psi], Cos[psi], 0 },
{ Sin[theta] Cos[psi], -Sin[psi], 0 },
{ Cos[theta], 0, 1 }
}
];
EulZYZToSpatialJac[phi_, theta_, psi_]:=
Module[{},
{{ 0, -Sin[phi], Cos[phi] Sin[theta] },
{ 0, Cos[phi], Sin[phi] Sin[theta] },
{ 1, 0, Cos[theta] }
}
];
EulZYZToBodyJac[phi_, theta_, psi_]:=
Module[{},
{{ -Cos[psi] Sin[theta], Sin[psi], 0 },
{ Sin[psi] Sin[theta], Cos[psi], 0 }
{ Cos[theta], 0, 1 }
}
];
EulZYXToSpatialJac[phi_, theta_, psi_]:=
Module[{},
{{ 0, -Sin[phi], Cos[theta] Cos[phi] },
{ 0, Cos[phi], Cos[theta] Sin[phi] },
{ 1, 0, -Sin[theta] }
}
];
EulZYXToBodyJac[phi_, theta_, psi_]:=
Module[{},
{{ -Sin[theta], 0, 1 }
{ Cos[theta] Sin[psi], Cos[psi], 0 }
{ Cos[theta] Cos[psi], -Sin[psi], 0 }
}
];
(* QuatToSpatialJac[ { b0_, b1_, b2_, b3_} ] :=
Module[{},
2 * { { -b1, b0, -b3, b2 },
{ -b2, b3, b0, -b1 },
{ -b3, -b2, b1, b0 }
}
]; *)
QuatToSpatialJac[ b0_, b1_, b2_, b3_ ] :=
Module[{},
2 * { { -b1, b0, -b3, b2 },
{ -b2, b3, b0, -b1 },
{ -b3, -b2, b1, b0 }
}
];
(* QuatToBodyJac[ { b0_, b1_, b2_, b3_} ] :=
Module[{},
2 * { { -b1, b0, b3, -b2 },
{ -b2, -b3, b0, b1 },
{ -b3, b2, -b1, b0 }
}
]; *)
QuatToBodyJac[ b0_, b1_, b2_, b3_ ] :=
Module[{},
2 * { { -b1, b0, b3, -b2 },
{ -b2, -b3, b0, b1 },
{ -b3, b2, -b1, b0 }
}
];
(* Parametrizations of SO(3) - Inverse Map *)
(* with theta \in (0, Pi) *)
MatToEulZYZ[R_] :=
Module[{phi, theta, psi, thetaiszero, thetaisPi},
(* Check the singularity of representation ZYZ *)
thetaiszero = Abs[ R[[3,3]] - 1] < 10^(-10);
thetaisPi = Abs[R[[3,3]] + 1] < 10^(-10);
(* In cases of singularity we set arbitrarily psi = 0 *)
If[ thetaiszero,
phi = ATan2[ R[[2,1]] , R[[1,1]] ];
theta = 0;
psi = 0;
];
If[ thetaisPi,
phi = ATan2[ R[[2,1]], R[[1,1]] ];
theta = Pi;
psi = 0;
];
If[ !(thetaiszero || thetaisPi),
phi = ATan2[R[[2,3]], R[[1,3]]];
theta = ATan2[Sqrt[ R[[1,3]]^2 + R[[2,3]]^2 ], R[[3,3]] ];
psi = ATan2[R[[3,2]], -R[[3,1]]];
];
Return[{phi, theta, psi}];
];
(* with theta \in (-Pi/2, Pi/2) *)
MatToEulZYX[R_] :=
Module[{phi, theta, psi, thetaisplushalfPi, thetaisminushalfPi},
(* Check the singularity of representation ZYX *)
thetaisplushalfPi = Abs[ R[[3,1]] + 1] < 10^(-10);
thetaisminushalfPi = Abs[R[[3,1]] - 1] < 10^(-10);
(* In cases of singularity we set arbitrarily psi = 0 *)
If[ thetaisplushalfPi,
phi = ATan2[ R[[2,3]] , R[[1,3]] ];
theta = Pi/2;
psi = 0;
];
If[ thetaisminushalfPi,
phi = ATan2[ -R[[2,3]], -R[[1,3]] ];
theta = -Pi/2;
psi = 0;
];
If[ !(thetaisplushalfPi || thetaisminushalfPi),
phi = ATan2[R[[2,1]], R[[1,1]]];
theta = ATan2[ -R[[3,1]], Sqrt[ R[[3,2]]^2 + R[[3,3]]^2 ] ];
psi = ATan2[ R[[3,2]], R[[3,3]] ];
];
Return[{phi, theta, psi}];
];
MatToRPY[R_] := MatToEulZYX[R];
FramesToVect[list_] :=
Module[{ R = list[[1]],
Rd = list[[2]],
hn, hs, ha,
nd, sd, ad,
eO },
hn = Hat[R[[All, 1]]];
hs = Hat[R[[All, 2]]];
ha = Hat[R[[All, 3]]];
nd = Rd[[All, 1]];
sd = Rd[[All, 2]];
ad = Rd[[All, 3]];
eO = (1/2) (hn.nd + hs.sd + ha.ad)
];
dexpInv[w_] :=
Module[{ dexpi, wnorm },
wnorm = Norm[w];
dexpi = Eye[3] - 0.5*Hat[w] - (wnorm Cot[wnorm/2] - 2)/(2 wnorm^2) Hat[w].Hat[w]
];
MatToVect[R_] :=
Module[{axis, theta},
{axis, theta} = RotationParam[R];
axis*Sin[theta]
]/; Length[R]==3
MatToVect[list_] :=
Module[{ R = list[[1]],
Rd = list[[2]],
hn, hs, ha,
nd, sd, ad,
eO },
hn = Hat[R[[All, 1]]];
hs = Hat[R[[All, 2]]];
ha = Hat[R[[All, 3]]];
nd = Rd[[All, 1]];
sd = Rd[[All, 2]];
ad = Rd[[All, 3]];
eO = (1/2) (hn.nd + hs.sd + ha.ad)
]/; Length[list]==2
(*