build.gradle

plugins {
    id 'forgified-fabric-loom' version '0.6.66'
    id 'maven-publish'
}

apply plugin: 'groovy'

sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

minecraft {
    accessWidener = file("src/main/resources/slight-gui-modifications.aw")
}

sourceSets {
    main {
        groovy { srcDirs += ['src/main/groovy'] }
    }
}

repositories {
    maven { 
        url "https://jitpack.io"
        
        content {
            includeGroup "com.github.Chocohead"
        }
    }
    maven { url "https://maven.shedaniel.me" }
    maven { url "https://maven.terraformersmc.com/releases" }
    jcenter {
        content {
            includeGroup "com.lettuce.fudge"
        }
    }
    mavenCentral()
}

dependencies {
    minecraft("com.mojang:minecraft:${project.minecraft_version}")
    mappings(minecraft.officialMojangMappings())
    optionally("net.fabricmc:fabric-loader:${project.loader_version}")

    modApi("net.fabricmc.fabric-api:fabric-api:${project.api_version}") {
        exclude(module: "fabric-biomes-v1")
    }
    depend("com.github.Chocohead:Fabric-ASM:${project.fabric_asm_version}")
    optionally("me.shedaniel:SmoothScrollingEverywhere:3.0.3-unstable")
    optionally("me.shedaniel:RoughlyEnoughItems:${project.rei_version}")
    optionally("com.terraformersmc:modmenu:${project.modmenu_version}")
    optionally("me.shedaniel:architectury:${project.architectury_version}:fabric")
    optionally("me.shedaniel.cloth:cloth-config:${project.cloth_config}:fabric")
    depend("me.shedaniel.cloth.api:cloth-client-events-v0:${project.cloth_api}")
    depend("com.lettuce.fudge:artifice:${project.artifice_version}")
    depend("org.codehaus.groovy:groovy-jsr223:3.0.3")
    depend("org.codehaus.groovy:groovy:3.0.3")
    compileOnly "com.google.code.findbugs:jsr305:3.0.2"
}

def depend(str) {
    dependencies.modApi(str) {
        exclude(group: "net.fabricmc")
        exclude(group: "net.fabricmc.fabric-api")
        exclude(group: "io.github.prospector")
        exclude(module: "config-2")
    }
    dependencies.include(str) {
        exclude(group: "net.fabricmc")
        exclude(group: "net.fabricmc.fabric-api")
        exclude(group: "io.github.prospector")
        exclude(module: "config-2")
    }
}

def optionally(str) {
    runtime(str)
    dependencies.modCompileOnly(str) {
        exclude(group: "net.fabricmc")
        exclude(group: "net.fabricmc.fabric-api")
        exclude(group: "io.github.prospector")
        exclude(module: "config-2")
    }
}

def runtime(str) {
    dependencies.modRuntime(str) {
        exclude(group: "net.fabricmc")
        exclude(group: "net.fabricmc.fabric-api")
        exclude(group: "io.github.prospector")
        exclude(module: "config-2")
    }
}

processResources {
    inputs.property "version", project.version

    from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand "version": project.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            // add all the jars that should be included when publishing to maven
            artifact(remapJar) {
                builtBy remapJar
            }
            artifact(sourcesJar) {
                builtBy remapSourcesJar
            }
        }
    }

    // select the repositories you want to publish to
    repositories {
        // uncomment to publish to the local maven
        // mavenLocal()
    }
}