generated from stacks-network/.github
-
Notifications
You must be signed in to change notification settings - Fork 19
/
Copy pathstandard.wat
4048 lines (3634 loc) · 191 KB
/
standard.wat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;; This module contains a standard library for Clarity, defining Clarity's
;; builtins, to be called from the generated Wasm code.
(module
(type (;0;) (func (param i32)))
(type (;1;) (func (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)))
(type (;2;) (func (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64 i64 i64)))
(type (;3;) (func (param i64 i64) (result i64 i64)))
(type (;4;) (func (param i32 i32 i32) (result i32)))
(type (;5;) (func (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)))
(type (;6;) (func (param $offset i32) (param $length i32) (param $offset-result i32) (result i32 i32)))
(type (;7;) (func (param $lo i64) (param $hi i64) (param $offset-result i32) (result i32 i32)))
(type (;8;) (func (param $bool_in i32) (result i32)))
(type (;9;) (func (param $offset_a i32) (param $length_a i32) (param $offset_b i32) (param $length_b i32) (result i32)))
;; Importing Clarity functions that are not natively available in WebAssembly.
;; Functions imported for host interface.
(import "clarity" "define_function" (func $stdlib.define_function (param $kind i32)
(param $name_offset i32)
(param $name_length i32)))
(import "clarity" "define_variable" (func $stdlib.define_variable (param $name_offset i32)
(param $name_length i32)
(param $initial_value_offset i32)
(param $initial_value_length i32)))
(import "clarity" "define_ft" (func $stdlib.define_ft (param $name_offset i32)
(param $name_length i32)
(param $supply_indicator i32)
(param $supply_lo i64)
(param $supply_hi i64)))
(import "clarity" "define_nft" (func $stdlib.define_nft (param $name_offset i32)
(param $name_length i32)))
(import "clarity" "define_map" (func $stdlib.define_map (param $name_offset i32)
(param $name_length i32)))
(import "clarity" "define_trait" (func $stdlib.define_trait (param $name_offset i32)
(param $name_length i32)))
(import "clarity" "impl_trait" (func $stdlib.impl_trait (param $trait_offset i32)
(param $trait_length i32)))
(import "clarity" "get_variable" (func $stdlib.get_variable (param $name_offset i32)
(param $name_length i32)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "set_variable" (func $stdlib.set_variable (param $name_offset i32)
(param $name_length i32)
(param $value_offset i32)
(param $value_length i32)))
(import "clarity" "print" (func $stdlib.print (param $value_offset i32)
(param $value_length i32)
(param $serialized_ty_offset i32)
(param $serialized_ty_length i32)))
(import "clarity" "enter_as_contract" (func $stdlib.enter_as_contract))
(import "clarity" "exit_as_contract" (func $stdlib.exit_as_contract))
(import "clarity" "enter_at_block" (func $stdlib.enter_at_block (param $block_hash_offset i32)
(param $block_hash_length i32)))
(import "clarity" "exit_at_block" (func $stdlib.exit_at_block))
(import "clarity" "stx_get_balance" (func $stdlib.stx_get_balance (param $principal_offset i32)
(param $principal_length i32)
(result i64 i64)))
(import "clarity" "stx_account" (func $stdlib.stx_account (param $principal_offset i32)
(param $principal_length i32)
(result i64 i64 i64 i64 i64 i64)))
(import "clarity" "stx_burn" (func $stdlib.stx_burn (param $amount_lo i64)
(param $amount_hi i64)
(param $principal_offset i32)
(param $principal_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "stx_transfer" (func $stdlib.stx_transfer (param $amount_lo i64)
(param $amount_hi i64)
(param $sender_offset i32)
(param $sender_length i32)
(param $recipient_offset i32)
(param $recipient_length i32)
(param $memo_offset i32)
(param $memo_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "ft_get_supply" (func $stdlib.ft_get_supply (param $name_offset i32)
(param $name_length i32)
(result i64 i64)))
(import "clarity" "ft_get_balance" (func $stdlib.ft_get_balance (param $name_offset i32)
(param $name_length i32)
(param $owner_offset i32)
(param $owner_length i32)
(result i64 i64)))
(import "clarity" "ft_burn" (func $stdlib.ft_burn (param $name_offset i32)
(param $name_length i32)
(param $amount_lo i64)
(param $amount_hi i64)
(param $sender_offset i32)
(param $sender_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "ft_mint" (func $stdlib.ft_mint (param $name_offset i32)
(param $name_length i32)
(param $amount_lo i64)
(param $amount_hi i64)
(param $sender_offset i32)
(param $sender_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "ft_transfer" (func $stdlib.ft_transfer (param $name_offset i32)
(param $name_length i32)
(param $amount_lo i64)
(param $amount_hi i64)
(param $sender_offset i32)
(param $sender_length i32)
(param $recipient_offset i32)
(param $recipient_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "nft_get_owner" (func $stdlib.nft_get_owner (param $name_offset i32)
(param $name_length i32)
(param $asset_offset i32)
(param $asset_length i32)
(param $return_offset i32)
(param $return_length i32)
(result i32 i32 i32)))
(import "clarity" "nft_burn" (func $stdlib.nft_burn (param $name_offset i32)
(param $name_length i32)
(param $asset_offset i32)
(param $asset_length i32)
(param $sender_offset i32)
(param $sender_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "nft_mint" (func $stdlib.nft_mint (param $name_offset i32)
(param $name_length i32)
(param $asset_offset i32)
(param $asset_length i32)
(param $recipient_offset i32)
(param $recipient_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "nft_transfer" (func $stdlib.nft_transfer (param $name_offset i32)
(param $name_length i32)
(param $asset_offset i32)
(param $asset_length i32)
(param $sender_offset i32)
(param $sender_length i32)
(param $recipient_offset i32)
(param $recipient_length i32)
(result i32 i32 i64 i64)))
(import "clarity" "map_get" (func $stdlib.map_get (param $name_offset i32)
(param $name_length i32)
(param $key_offset i32)
(param $key_length i32)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "map_set" (func $stdlib.map_set (param $name_offset i32)
(param $name_length i32)
(param $key_offset i32)
(param $key_length i32)
(param $value_offset i32)
(param $value_length i32)
(result i32)))
(import "clarity" "map_insert" (func $stdlib.map_insert (param $name_offset i32)
(param $name_length i32)
(param $key_offset i32)
(param $key_length i32)
(param $value_offset i32)
(param $value_length i32)
(result i32)))
(import "clarity" "map_delete" (func $stdlib.map_delete (param $name_offset i32)
(param $name_length i32)
(param $key_offset i32)
(param $key_length i32)
(result i32)))
(import "clarity" "get_block_info_time_property" (func $stdlib.get_block_info_time_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_vrf_seed_property" (func $stdlib.get_block_info_vrf_seed_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_header_hash_property" (func $stdlib.get_block_info_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_burnchain_header_hash_property" (func $stdlib.get_block_info_burnchain_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_identity_header_hash_property" (func $stdlib.get_block_info_identity_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_miner_address_property" (func $stdlib.get_block_info_miner_address_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_miner_spend_winner_property" (func $stdlib.get_block_info_miner_spend_winner_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_miner_spend_total_property" (func $stdlib.get_block_info_miner_spend_total_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_block_info_block_reward_property" (func $stdlib.get_block_info_block_reward_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_burn_block_info_header_hash_property" (func $stdlib.get_burn_block_info_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_burn_block_info_pox_addrs_property" (func $stdlib.get_burn_block_info_pox_addrs_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_stacks_block_info_time_property" (func $stdlib.get_stacks_block_info_time_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_stacks_block_info_header_hash_property" (func $stdlib.get_stacks_block_info_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_stacks_block_info_identity_header_hash_property" (func $stdlib.get_stacks_block_info_identity_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_burnchain_header_hash_property" (func $stdlib.get_tenure_info_burnchain_header_hash_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_miner_address_property" (func $stdlib.get_tenure_info_miner_address_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_time_property" (func $stdlib.get_tenure_info_time_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_vrf_seed_property" (func $stdlib.get_tenure_info_vrf_seed_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_block_reward_property" (func $stdlib.get_tenure_info_block_reward_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_miner_spend_total_property" (func $stdlib.get_tenure_info_miner_spend_total_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "get_tenure_info_miner_spend_winner_property" (func $stdlib.get_tenure_info_miner_spend_winner_property (param $height_lo i64)
(param $height_hi i64)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "contract_call" (func $stdlib.contract_call (param $trait_name_offset i32)
(param $trait_name_len i32)
(param $contract_id_offset i32)
(param $contract_id_length i32)
(param $function_name_offset i32)
(param $function_name_length i32)
(param $arguments_offset i32)
(param $arguments_length i32)
(param $return_offset i32)
(param $return_length i32)))
(import "clarity" "begin_public_call" (func $stdlib.begin_public_call))
(import "clarity" "begin_read_only_call" (func $stdlib.begin_read_only_call))
(import "clarity" "commit_call" (func $stdlib.commit_call))
(import "clarity" "roll_back_call" (func $stdlib.roll_back_call))
(import "clarity" "keccak256" (func $stdlib.keccak256 (param $buffer_offset i32)
(param $buffer_length i32)
(param $result_offset i32)
(param $result_length i32)
(result i32 i32)))
(import "clarity" "sha512_256" (func $stdlib.sha512_256 (param $buffer_offset i32)
(param $buffer_length i32)
(param $result_offset i32)
(param $result_length i32)
(result i32 i32)))
(import "clarity" "secp256k1_recover" (func $stdlib.secp256k1_recover (param $msg_offset i32)
(param $msg_length i32)
(param $sig_offset i32)
(param $sig_length i32)
(param $result_offset i32)
(param $result_length i32)))
(import "clarity" "secp256k1_verify" (func $stdlib.secp256k1_verify (param $msg_offset i32)
(param $msg_length i32)
(param $sig_offset i32)
(param $sig_length i32)
(param $pk_offset i32)
(param $pk_length i32)
(result i32)))
(import "clarity" "principal_of" (func $stdlib.principal_of (param $key_offset i32)
(param $key_length i32)
(param $principal_offset i32)
(result i32 i32 i32 i64 i64)))
(import "clarity" "tx_sender" (func $stdlib.tx_sender (param $return_offset i32)
(param $return_length i32)
(result i32 i32)))
(import "clarity" "contract_caller" (func $stdlib.contract_caller (param $return_offset i32)
(param $return_length i32)
(result i32 i32)))
(import "clarity" "tx_sponsor" (func $stdlib.tx_sponsor (param $return_offset i32)
(param $return_length i32)
(result i32 i32 i32)))
(import "clarity" "block_height" (func $stdlib.block_height (result i64 i64)))
(import "clarity" "stacks_block_height" (func $stdlib.stacks_block_height (result i64 i64)))
(import "clarity" "tenure_height" (func $stdlib.tenure_height (result i64 i64)))
(import "clarity" "burn_block_height" (func $stdlib.burn_block_height (result i64 i64)))
(import "clarity" "stx_liquid_supply" (func $stdlib.stx_liquid_supply (result i64 i64)))
(import "clarity" "save_constant"
(func $stdlib.save_constant
(param $name_offset i32)
(param $name_length i32)
(param $value_offset i32)
(param $value_length i32)))
(import "clarity" "load_constant"
(func $stdlib.load_constant
(param $name_offset i32)
(param $name_length i32)
(param $value_offset i32)
(param $value_length i32)))
(import "clarity" "skip_list" (func $skip-list (param $offset i32) (param $offset_end i32) (result i32)))
;; TODO: these three funcs below could be hard-coded at compile-time.
(import "clarity" "is_in_regtest" (func $stdlib.is_in_regtest (result i32)))
(import "clarity" "is_in_mainnet" (func $stdlib.is_in_mainnet (result i32)))
(import "clarity" "chain_id" (func $stdlib.chain_id (result i64 i64)))
;; Useful for debugging, just prints the value
(import "" "log" (func $log (param $value i64)))
;; Useful for debugging, just prints a message
(import "" "debug_msg" (func $debug_msg (param $value i32)))
;;
;; Global definitions
(global $stack-pointer (mut i32) (i32.const 0))
(global $runtime-error-code (mut i32) (i32.const -1))
(global $runtime-error-arg-offset (mut i32) (i32.const -1))
(global $runtime-error-arg-len (mut i32) (i32.const -1))
(global $runtime-error-value-offset (mut i32) (i32.const -1))
(global $runtime-error-type-ser-offset (mut i32) (i32.const -1))
(global $runtime-error-type-ser-len (mut i32) (i32.const -1))
;; (sha256) initial hash values: first 32 bits of the fractional parts of the square roots of the first 8 primes 2..19
(data (i32.const 0) "\67\e6\09\6a\85\ae\67\bb\72\f3\6e\3c\3a\f5\4f\a5\7f\52\0e\51\8c\68\05\9b\ab\d9\83\1f\19\cd\e0\5b")
;; (sha256) K constants: first 32 bits of the fractional parts of the cube roots of the first 64 primes 2..311
(data (i32.const 32) "\98\2f\8a\42\91\44\37\71\cf\fb\c0\b5\a5\db\b5\e9\5b\c2\56\39\f1\11\f1\59\a4\82\3f\92\d5\5e\1c\ab\98\aa\07\d8\01\5b\83\12\be\85\31\24\c3\7d\0c\55\74\5d\be\72\fe\b1\de\80\a7\06\dc\9b\74\f1\9b\c1\c1\69\9b\e4\86\47\be\ef\c6\9d\c1\0f\cc\a1\0c\24\6f\2c\e9\2d\aa\84\74\4a\dc\a9\b0\5c\da\88\f9\76\52\51\3e\98\6d\c6\31\a8\c8\27\03\b0\c7\7f\59\bf\f3\0b\e0\c6\47\91\a7\d5\51\63\ca\06\67\29\29\14\85\0a\b7\27\38\21\1b\2e\fc\6d\2c\4d\13\0d\38\53\54\73\0a\65\bb\0a\6a\76\2e\c9\c2\81\85\2c\72\92\a1\e8\bf\a2\4b\66\1a\a8\70\8b\4b\c2\a3\51\6c\c7\19\e8\92\d1\24\06\99\d6\85\35\0e\f4\70\a0\6a\10\16\c1\a4\19\08\6c\37\1e\4c\77\48\27\b5\bc\b0\34\b3\0c\1c\39\4a\aa\d8\4e\4f\ca\9c\5b\f3\6f\2e\68\ee\82\8f\74\6f\63\a5\78\14\78\c8\84\08\02\c7\8c\fa\ff\be\90\eb\6c\50\a4\f7\a3\f9\be\f2\78\71\c6")
;; (hash-160) selection of message word (r)
(data (i32.const 288) "\00\01\02\03\04\05\06\07\08\09\0a\0b\0c\0d\0e\0f\07\04\0d\01\0a\06\0f\03\0c\00\09\05\02\0e\0b\08\03\0a\0e\04\09\0f\08\01\02\07\00\06\0d\0b\05\0c\01\09\0b\0a\00\08\0c\04\0d\03\07\0f\0e\05\06\02\04\00\05\09\07\0c\02\0a\0e\01\03\08\0b\06\0f\0d")
;; (hash-160) selection of message word (r')
(data (i32.const 368) "\05\0e\07\00\09\02\0b\04\0d\06\0f\08\01\0a\03\0c\06\0b\03\07\00\0d\05\0a\0e\0f\08\0c\04\09\01\02\0f\05\01\03\07\0e\06\09\0b\08\0c\02\0a\00\04\0d\08\06\04\01\03\0b\0f\00\05\0c\02\0d\09\07\0a\0e\0c\0f\0a\04\01\05\08\07\06\02\0d\0e\00\03\09\0b")
;; (hash-160) rotate-left amount (s)
(data (i32.const 448) "\0b\0e\0f\0c\05\08\07\09\0b\0d\0e\0f\06\07\09\08\07\06\08\0d\0b\09\07\0f\07\0c\0f\09\0b\07\0d\0c\0b\0d\06\07\0e\09\0d\0f\0e\08\0d\06\05\0c\07\05\0b\0c\0e\0f\0e\0f\09\08\09\0e\05\06\08\06\05\0c\09\0f\05\0b\06\08\0d\0c\05\0c\0d\0e\0b\08\05\06")
;; (hash-160) rotate-left amount (s')
(data (i32.const 528) "\08\09\09\0b\0d\0f\0f\05\07\07\08\0b\0e\0e\0c\06\09\0d\0f\07\0c\08\09\0b\07\07\0c\07\06\0f\0d\0b\09\07\0f\0b\08\06\06\0e\0c\0d\05\0e\0d\0d\07\05\0f\05\08\0b\0e\0e\06\0e\06\09\0c\09\0c\05\0f\08\08\05\0c\09\0c\05\0e\06\08\0d\06\05\0f\0d\0b\0b")
;; (hash-160) K constants
(data (i32.const 608) "\00\00\00\00\99\79\82\5a\a1\eb\d9\6e\dc\bc\1b\8f\4e\fd\53\a9")
;; (hash-160) K' constants
(data (i32.const 628) "\e6\8b\a2\50\24\d1\4d\5c\f3\3e\70\6d\e9\76\6d\7a\00\00\00\00")
;; sha512 initial values (64 bytes)
(data (i32.const 648) "\08\c9\bc\f3\67\e6\09\6a\3b\a7\ca\84\85\ae\67\bb\2b\f8\94\fe\72\f3\6e\3c\f1\36\1d\5f\3a\f5\4f\a5\d1\82\e6\ad\7f\52\0e\51\1f\6c\3e\2b\8c\68\05\9b\6b\bd\41\fb\ab\d9\83\1f\79\21\7e\13\19\cd\e0\5b")
;; sha512 K constants
(data (i32.const 712) "\22\ae\28\d7\98\2f\8a\42\cd\65\ef\23\91\44\37\71\2f\3b\4d\ec\cf\fb\c0\b5\bc\db\89\81\a5\db\b5\e9\38\b5\48\f3\5b\c2\56\39\19\d0\05\b6\f1\11\f1\59\9b\4f\19\af\a4\82\3f\92\18\81\6d\da\d5\5e\1c\ab\42\02\03\a3\98\aa\07\d8\be\6f\70\45\01\5b\83\12\8c\b2\e4\4e\be\85\31\24\e2\b4\ff\d5\c3\7d\0c\55\6f\89\7b\f2\74\5d\be\72\b1\96\16\3b\fe\b1\de\80\35\12\c7\25\a7\06\dc\9b\94\26\69\cf\74\f1\9b\c1\d2\4a\f1\9e\c1\69\9b\e4\e3\25\4f\38\86\47\be\ef\b5\d5\8c\8b\c6\9d\c1\0f\65\9c\ac\77\cc\a1\0c\24\75\02\2b\59\6f\2c\e9\2d\83\e4\a6\6e\aa\84\74\4a\d4\fb\41\bd\dc\a9\b0\5c\b5\53\11\83\da\88\f9\76\ab\df\66\ee\52\51\3e\98\10\32\b4\2d\6d\c6\31\a8\3f\21\fb\98\c8\27\03\b0\e4\0e\ef\be\c7\7f\59\bf\c2\8f\a8\3d\f3\0b\e0\c6\25\a7\0a\93\47\91\a7\d5\6f\82\03\e0\51\63\ca\06\70\6e\0e\0a\67\29\29\14\fc\2f\d2\46\85\0a\b7\27\26\c9\26\5c\38\21\1b\2e\ed\2a\c4\5a\fc\6d\2c\4d\df\b3\95\9d\13\0d\38\53\de\63\af\8b\54\73\0a\65\a8\b2\77\3c\bb\0a\6a\76\e6\ae\ed\47\2e\c9\c2\81\3b\35\82\14\85\2c\72\92\64\03\f1\4c\a1\e8\bf\a2\01\30\42\bc\4b\66\1a\a8\91\97\f8\d0\70\8b\4b\c2\30\be\54\06\a3\51\6c\c7\18\52\ef\d6\19\e8\92\d1\10\a9\65\55\24\06\99\d6\2a\20\71\57\85\35\0e\f4\b8\d1\bb\32\70\a0\6a\10\c8\d0\d2\b8\16\c1\a4\19\53\ab\41\51\08\6c\37\1e\99\eb\8e\df\4c\77\48\27\a8\48\9b\e1\b5\bc\b0\34\63\5a\c9\c5\b3\0c\1c\39\cb\8a\41\e3\4a\aa\d8\4e\73\e3\63\77\4f\ca\9c\5b\a3\b8\b2\d6\f3\6f\2e\68\fc\b2\ef\5d\ee\82\8f\74\60\2f\17\43\6f\63\a5\78\72\ab\f0\a1\14\78\c8\84\ec\39\64\1a\08\02\c7\8c\28\1e\63\23\fa\ff\be\90\e9\bd\82\de\eb\6c\50\a4\15\79\c6\b2\f7\a3\f9\be\2b\53\72\e3\f2\78\71\c6\9c\61\26\ea\ce\3e\27\ca\07\c2\c0\21\c7\b8\86\d1\1e\eb\e0\cd\d6\7d\da\ea\78\d1\6e\ee\7f\4f\7d\f5\ba\6f\17\72\aa\67\f0\06\a6\98\c8\a2\c5\7d\63\0a\ae\0d\f9\be\04\98\3f\11\1b\47\1c\13\35\0b\71\1b\84\7d\04\23\f5\77\db\28\93\24\c7\40\7b\ab\ca\32\bc\be\c9\15\0a\be\9e\3c\4c\0d\10\9c\c4\67\1d\43\b6\42\3e\cb\be\d4\c5\4c\2a\7e\65\fc\9c\29\7f\59\ec\fa\d6\3a\ab\6f\cb\5f\17\58\47\4a\8c\19\44\6c")
;; table that contains the 5 hash160 functions used during compression
(table 20 funcref)
;; table that contains the 5 hash160 functions used during compression (index 0 to 4)
(type $hash160-compress-function (func (param i32 i32 i32 i32) (result i32)))
(elem (i32.const 0) $hash160-f1 $hash160-f2 $hash160-f3 $hash160-f4 $hash160-f5)
;; table that contains the skip functions for tuple deserialization (index 5 to 19)
(type $skip-function (func (param i32 i32) (result i32)))
(elem (i32.const 5) $skip-int128 $skip-int128 $skip-buffer $skip-boolean-or-none $skip-boolean-or-none $skip-principal $skip-contract $skip-some-ok-err $skip-some-ok-err $skip-boolean-or-none $skip-some-ok-err $skip-list $skip-tuple $skip-string-ascii $skip-string-utf8)
;; The error code is one of:
;; 0: overflow
;; 1: underflow
;; 2: divide by zero
;; 3: log of a number <= 0
;; 4: expected a non-negative number
;; 5: buffer to integer expects a buffer length <= 16
;; 6: panic
;; 7: short return
(func $stdlib.runtime-error (param $error_code i32)
(global.set $runtime-error-code (local.get $error_code))
(unreachable)
)
;; This function can be used to add either signed or unsigned integers
(func $stdlib.add-int128 (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
;; Add the lower 64 bits
(local.tee $b_lo (i64.add (local.get $a_lo) (local.get $b_lo))) ;; $b_lo now contains the result lower bits
;; Add the upper 64 bits, accounting for any carry from the lower bits
(i64.add
(i64.extend_i32_u (i64.gt_u (local.get $a_lo) (local.get $b_lo))) ;; carry
(i64.add (local.get $a_hi) (local.get $b_hi))) ;; upper 64 bits
)
(func $stdlib.add-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(local $sum_hi i64)
(local $sum_lo i64)
(local.get $a_lo)
(local.get $a_hi)
(local.get $b_lo)
(local.get $b_hi)
(call $stdlib.add-int128)
(local.set $sum_hi)
(local.set $sum_lo)
;; Check for overflow and underflow
(if (i64.eq (i64.shr_s (local.get $a_hi) (i64.const 63)) (i64.shr_s (local.get $b_hi) (i64.const 63))) ;; if a and b have the same sign
(then
(if (i64.ne (i64.shr_s (local.get $a_hi) (i64.const 63)) (i64.shr_s (local.get $sum_hi) (i64.const 63))) ;; and the result has a different sign
(then (call $stdlib.runtime-error (i32.const 0)))
)
)
)
;; Return the result
(return (local.get $sum_lo) (local.get $sum_hi))
)
(func $stdlib.add-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(call $stdlib.add-int128 (local.get $a_lo) (local.get $a_hi) (local.get $b_lo) (local.get $b_hi))
(local.set $a_hi) ;; storing the result in place of first operand
(local.set $a_lo)
;; overflow condition: sum (a) < operand (b)
(if (call $stdlib.lt-uint (local.get $a_lo) (local.get $a_hi) (local.get $b_lo) (local.get $b_hi))
(then (call $stdlib.runtime-error (i32.const 0)))
)
(local.get $a_lo) (local.get $a_hi)
)
;; This function can be used to subtract either signed or unsigned integers
(func $stdlib.sub-int128 (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(local $borrow i64)
(local $diff_lo i64)
(local $diff_hi i64)
;; Calculate borrow
(local.set $borrow (i64.extend_i32_u (i64.lt_u (local.get $a_lo) (local.get $b_lo))))
;; Calculate diff_lo
(local.set $diff_lo (i64.sub (local.get $a_lo) (local.get $b_lo)))
;; Calculate diff_hi
(local.set $diff_hi (i64.sub (i64.sub (local.get $a_hi) (local.get $b_hi)) (local.get $borrow)))
;; Return the result
(return (local.get $diff_lo) (local.get $diff_hi))
)
(func $stdlib.sub-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(local $diff_hi i64)
(local $diff_lo i64)
(local.get $a_lo)
(local.get $a_hi)
(local.get $b_lo)
(local.get $b_hi)
(call $stdlib.sub-int128)
(local.set $diff_hi)
(local.set $diff_lo)
;; Check for overflow and underflow
(if (i64.ne (i64.shr_s (local.get $a_hi) (i64.const 63)) (i64.shr_s (local.get $b_hi) (i64.const 63))) ;; if a and b have different signs
(then
(if (i64.ne (i64.shr_s (local.get $a_hi) (i64.const 63)) (i64.shr_s (local.get $diff_hi) (i64.const 63))) ;; and the result has a different sign from a
(then (call $stdlib.runtime-error (i32.const 1)))
)
)
)
;; Return the result
(return (local.get $diff_lo) (local.get $diff_hi))
)
(func $stdlib.sub-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(local $diff_hi i64)
(local $diff_lo i64)
(local.get $a_lo)
(local.get $a_hi)
(local.get $b_lo)
(local.get $b_hi)
(call $stdlib.sub-int128)
(local.set $diff_hi)
(local.set $diff_lo)
;; Check for underflow
(if (i64.gt_u (local.get $diff_hi) (local.get $a_hi))
(then (call $stdlib.runtime-error (i32.const 1)))
)
;; Return the result
(return (local.get $diff_lo) (local.get $diff_hi))
)
(func $stdlib.mul-int128 (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
;; Adaptation of Hacker's Delight, chapter 8
;; u1 <- $a_lo & 0xffffffff; v1 <- $b_lo & 0xffffffff
;; u2 <- $a_lo >> 32; v2 <- $b_lo >> 32
;; t1 <- v1 * u1
;; t2 <- (u2 * v1) + (t1 >> 32)
;; t3 <- (u1 * v2) + (t2 & 0xffffffff)
;; $res_lo <- (t3 << 32) | (t1 & 0xffffffff)
;; $res_hi <- ($a_lo * b_hi) + ($a_hi * b_lo) + (v2 * u2) + (t2 >> 32) + (t3 >> 32)
(local $u2 i64) (local $v2 i64) (local $t1 i64) (local $t2 i64) (local $t3 i64)
;;;;;;;;;;;;;;;;;;;;;;;;;;;; res_lo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(local.tee $t1
(i64.mul
;; $v2 contains u1 temporarily
(local.tee $v2 (i64.and (local.get $a_lo) (i64.const 0xffffffff)))
;; $u2 contains v1 temporarily
(local.tee $u2 (i64.and (local.get $b_lo) (i64.const 0xffffffff)))
)
)
(i64.shr_u (i64.const 32)) ;; (t1 >> 32)
(i64.mul ;; (u2 * v1)
(local.get $u2) ;; contains v1 at that point
(local.tee $u2 (i64.shr_u (local.get $a_lo) (i64.const 32)))
)
(local.tee $t2 (i64.add)) ;; (u2 * v1) + (t1 >> 32)
(i64.and (i64.const 0xffffffff)) ;; (t2 & 0xffffffff)
(i64.mul ;; (u1 * v2)
(local.get $v2) ;; contains u1 at that point
(local.tee $v2 (i64.shr_u (local.get $b_lo) (i64.const 32)))
)
(local.tee $t3 (i64.add)) ;; (u1 * v2) + (t2 & 0xffffffff)
(i64.shl (i64.const 32)) ;; (t3 << 32)
(i64.and (local.get $t1) (i64.const 0xffffffff))
i64.or ;; (t2 << 32) | (t1 & 0xffffffff)
;;;;;;;;;;;;;;;;;;;;;;;;;;;; res_hi ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(i64.mul (local.get $a_lo) (local.get $b_hi))
(i64.add (i64.mul (local.get $a_hi) (local.get $b_lo)))
(i64.add (i64.mul (local.get $v2) (local.get $u2)))
(i64.add (i64.shr_u (local.get $t2) (i64.const 32)))
(i64.add (i64.shr_u (local.get $t3) (i64.const 32)))
)
(func $stdlib.mul-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(local $tmp i32)
(local.set $tmp ;; tmp contains the sum of number of leading zeros of arguments
(i32.add
(call $clz-int128 (local.get $a_lo) (local.get $a_hi))
(call $clz-int128 (local.get $b_lo) (local.get $b_hi))
)
)
(if (i32.ge_u (local.get $tmp) (i32.const 128))
(then
;; product cannot overflow if the sum of leading zeros is >= 128
(return (call $stdlib.mul-int128 (local.get $a_lo) (local.get $a_hi) (local.get $b_lo) (local.get $b_hi)))
)
)
(if (i32.le_u (local.get $tmp) (i32.const 126))
(then
;; product will overflow if the sum of leading zeros is <= 126
(call $stdlib.runtime-error (i32.const 0))
)
)
;; Other case might overflow. We compute (a * b/2) and check if result > 2**127
;; -> if yes, overflow
;; -> if not, we double the product, and add a one more time if b was odd
;; tmp is 1 if b was odd else 0
(local.set $tmp (i32.wrap_i64 (i64.and (local.get $b_lo) (i64.const 1))))
;; b / 2
(i64.or
(i64.shl (local.get $b_hi) (i64.const 63))
(i64.shr_u (local.get $b_lo) (i64.const 1))
)
(i64.shr_u (local.get $b_hi) (i64.const 1))
;; a * b/2
(call $stdlib.mul-int128 (local.get $a_lo) (local.get $a_hi))
;; b contains the result from now on
(local.set $b_hi)
(local.set $b_lo)
;; if result/2 > 2**127 overflow
(if (i64.lt_s (local.get $b_hi) (i64.const 0))
(then (call $stdlib.runtime-error (i32.const 0)))
)
;; res *= 2, meaning res <<= 1
(local.set $b_hi
(i64.or
(i64.shl (local.get $b_hi) (i64.const 1))
(i64.shr_u (local.get $b_lo) (i64.const 63))
)
)
(local.set $b_lo (i64.shl (local.get $b_lo) (i64.const 1)))
;; if b is odd ($tmp), we add a
(if (local.get $tmp)
(then
(call $stdlib.add-uint (local.get $b_lo) (local.get $b_hi) (local.get $a_lo) (local.get $a_hi))
(local.set $b_hi)
(local.set $b_lo)
)
)
(local.get $b_lo) (local.get $b_hi)
)
(func $stdlib.mul-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i64 i64)
(local $sign i32)
;; this is a shortcut for a multiplication by 1.
;; also, it prevents us from dealing with the infamous abs(i128::MIN), and
;; the only operation that would work on that number would be (i128::MIN * 1)
(if (i64.eqz (i64.or (local.get $a_hi) (i64.xor (local.get $a_lo) (i64.const 1))))
(then (return (local.get $b_lo) (local.get $b_hi)))
)
(if (i64.eqz (i64.or (local.get $b_hi) (i64.xor (local.get $b_lo) (i64.const 1))))
(then (return (local.get $a_lo) (local.get $a_hi)))
)
;; take the absolute value of the operands, and compute the expected sign in 3 steps:
;; 1. Absolute value of a
;; NOTE: the absolute value algorithm was generated from
;; `fn abs(a: i128) -> i128 { a.abs() }`
(select
(i64.sub (i64.const 0) (local.get $a_lo))
(local.get $a_lo)
(local.tee $sign (i64.lt_s (local.get $a_hi) (i64.const 0))) ;; sign is the sign bit of a
)
(select
(i64.sub (i64.const 0) (i64.add (local.get $a_hi) (i64.extend_i32_u (i64.ne (local.get $a_lo) (i64.const 0)))))
(local.get $a_hi)
(local.get $sign)
)
;; 2. Absolute value of b
(select
(i64.sub (i64.const 0) (local.get $b_lo))
(local.get $b_lo)
(local.tee $sign (i64.lt_s (local.get $b_hi) (i64.const 0))) ;; sign is sign bit of b now
)
(select
(i64.sub (i64.const 0) (i64.add (local.get $b_hi) (i64.extend_i32_u (i64.ne (local.get $b_lo) (i64.const 0)))))
(local.get $b_hi)
(local.get $sign)
)
;; 3. Compute expected sign
(local.set $sign
(i32.xor
(i64.lt_s (local.get $a_hi) (i64.const 0)) ;; sign of a
(local.get $sign) ;; sign is sign of b
)
)
(call $stdlib.mul-uint)
(local.set $a_hi)
(local.set $a_lo)
;; Sign bit should be 0, otherwise there is an overflow
(if (i64.lt_s (local.get $a_hi) (i64.const 0))
(then (call $stdlib.runtime-error (i32.const 0)))
)
;; Return the result and adapt with sign bit
(select
(i64.sub (i64.const 0) (local.get $a_lo))
(local.get $a_lo)
(local.get $sign)
)
(select
(i64.sub (i64.const 0) (i64.add (local.get $a_hi) (i64.extend_i32_u (i64.ne (local.get $a_lo) (i64.const 0)))))
(local.get $a_hi)
(local.get $sign)
)
)
(func $stdlib.div-int128 (param $dividend_lo i64) (param $dividend_hi i64) (param $divisor_lo i64) (param $divisor_hi i64) (result i64 i64 i64 i64)
(local $quotient_hi i64)
(local $quotient_lo i64)
(local $remainder_hi i64)
(local $remainder_lo i64)
(local $current_bit i64)
;; Check for division by 0
(if (i64.eqz (i64.or (local.get $divisor_hi) (local.get $divisor_lo)))
(then (call $stdlib.runtime-error (i32.const 2)))
)
;; Long division algorithm
;; Initialize the quotient and remainder to 0
(local.set $quotient_hi (i64.const 0))
(local.set $quotient_lo (i64.const 0))
(local.set $remainder_hi (i64.const 0))
(local.set $remainder_lo (i64.const 0))
;; (local.set $remainder_hi (local.get $dividend_hi))
;; (local.set $remainder_lo (local.get $dividend_lo))
;; Use current_bit to loop over the bits of the dividend
(local.set $current_bit (i64.const 127))
(loop $div_loop
;; Shift the remainder left by one bit,
;; filling the least significant bit with the next bit of the dividend
(local.set $remainder_hi (i64.or
(i64.shl (local.get $remainder_hi) (i64.const 1))
(i64.shr_u (local.get $remainder_lo) (i64.const 63))))
(local.set $remainder_lo (i64.or
(i64.shl (local.get $remainder_lo) (i64.const 1))
(i64.shr_u (local.get $dividend_hi) (i64.const 63))))
;; Shift the dividend left by one bit
(local.set $dividend_hi (i64.or
(i64.shl (local.get $dividend_hi) (i64.const 1))
(i64.shr_u (local.get $dividend_lo) (i64.const 63))))
(local.set $dividend_lo (i64.shl (local.get $dividend_lo) (i64.const 1)))
;; If the remainder is greater than or equal to the divisor,
(if (i32.or (i64.gt_u (local.get $remainder_hi) (local.get $divisor_hi))
(i32.and (i64.eq (local.get $remainder_hi) (local.get $divisor_hi))
(i64.ge_u (local.get $remainder_lo) (local.get $divisor_lo))))
(then
;; Subtract the divisor from the remainder
(call $stdlib.sub-int128 (local.get $remainder_lo) (local.get $remainder_hi) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $remainder_hi)
(local.set $remainder_lo)
;; and set the current bit of the quotient to 1
(if (i64.lt_u (local.get $current_bit) (i64.const 64))
(then
(local.set $quotient_lo (i64.or (local.get $quotient_lo)
(i64.shl (i64.const 1) (local.get $current_bit))))
)
(else
(local.set $quotient_hi (i64.or (local.get $quotient_hi)
(i64.shl (i64.const 1) (i64.sub (local.get $current_bit) (i64.const 64)))))
)
)
)
)
;; Decrement the current bit and loop until all bits have been processed
(local.set $current_bit (i64.sub (local.get $current_bit) (i64.const 1)))
(br_if $div_loop (i64.ge_s (local.get $current_bit) (i64.const 0)))
)
;; Return the quotient and the remainder
(return (local.get $quotient_lo) (local.get $quotient_hi) (local.get $remainder_lo) (local.get $remainder_hi))
)
(func $stdlib.div-uint (param $dividend_lo i64) (param $dividend_hi i64) (param $divisor_lo i64) (param $divisor_hi i64) (result i64 i64)
(local $quotient_hi i64)
(local $quotient_lo i64)
(local $remainder_hi i64)
(local $remainder_lo i64)
(call $stdlib.div-int128 (local.get $dividend_lo) (local.get $dividend_hi) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $remainder_hi)
(local.set $remainder_lo)
(local.set $quotient_hi)
(local.set $quotient_lo)
(return (local.get $quotient_lo) (local.get $quotient_hi))
)
(func $stdlib.div-int (param $dividend_lo i64) (param $dividend_hi i64) (param $divisor_lo i64) (param $divisor_hi i64) (result i64 i64)
(local $quotient_hi i64)
(local $quotient_lo i64)
(local $remainder_hi i64)
(local $remainder_lo i64)
(local $sign_dividend i64)
(local $sign_divisor i64)
(local $expected_sign i64)
;; overflow if i128::MIN / -1
(if
(i32.and
(i32.and (i64.eqz (local.get $dividend_lo)) (i64.eq (local.get $dividend_hi) (i64.const 0x8000000000000000)))
(i64.eq (i64.and (local.get $divisor_lo) (local.get $divisor_hi)) (i64.const -1))
)
(then (call $stdlib.runtime-error (i32.const 0)))
)
;; Compute the expected sign of the result
(local.set $sign_dividend (i64.shr_s (local.get $dividend_hi) (i64.const 63)))
(local.set $sign_divisor (i64.shr_s (local.get $divisor_hi) (i64.const 63)))
(local.set $expected_sign (i64.xor (local.get $sign_dividend) (local.get $sign_divisor)))
;; Perform the division using the absolute values of the operands
(if (i32.wrap_i64 (local.get $sign_dividend))
(then
(call $stdlib.sub-int128 (i64.const 0) (i64.const 0) (local.get $dividend_lo) (local.get $dividend_hi))
(local.set $dividend_hi)
(local.set $dividend_lo)
)
)
(if (i32.wrap_i64 (local.get $sign_divisor))
(then
(call $stdlib.sub-int128 (i64.const 0) (i64.const 0) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $divisor_hi)
(local.set $divisor_lo)
)
)
(call $stdlib.div-int128 (local.get $dividend_lo) (local.get $dividend_hi) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $remainder_hi)
(local.set $remainder_lo)
(local.set $quotient_hi)
(local.set $quotient_lo)
;; If the result should be negative, negate it
(if (i32.wrap_i64 (local.get $expected_sign))
(then
(call $stdlib.sub-int128 (i64.const 0) (i64.const 0) (local.get $quotient_lo) (local.get $quotient_hi))
(local.set $quotient_hi)
(local.set $quotient_lo)
)
)
(return (local.get $quotient_lo) (local.get $quotient_hi))
)
(func $stdlib.mod-uint (param $dividend_lo i64) (param $dividend_hi i64) (param $divisor_lo i64) (param $divisor_hi i64) (result i64 i64)
(local $quotient_hi i64)
(local $quotient_lo i64)
(local $remainder_hi i64)
(local $remainder_lo i64)
(call $stdlib.div-int128 (local.get $dividend_lo) (local.get $dividend_hi) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $remainder_hi)
(local.set $remainder_lo)
(local.set $quotient_hi)
(local.set $quotient_lo)
(return (local.get $remainder_lo) (local.get $remainder_hi))
)
(func $stdlib.mod-int (param $dividend_lo i64) (param $dividend_hi i64) (param $divisor_lo i64) (param $divisor_hi i64) (result i64 i64)
(local $quotient_hi i64)
(local $quotient_lo i64)
(local $remainder_hi i64)
(local $remainder_lo i64)
(local $sign_dividend i64)
(local $sign_divisor i64)
(local $expected_sign i64)
;; Compute the expected sign of the result
(local.set $sign_dividend (i64.shr_s (local.get $dividend_hi) (i64.const 63)))
(local.set $sign_divisor (i64.shr_s (local.get $divisor_hi) (i64.const 63)))
(local.set $expected_sign (i64.xor (local.get $sign_dividend) (local.get $sign_divisor)))
;; Perform the division using the absolute values of the operands
(if (i32.wrap_i64 (local.get $sign_dividend))
(then
(call $stdlib.sub-int128 (i64.const 0) (i64.const 0) (local.get $dividend_lo) (local.get $dividend_hi))
(local.set $dividend_hi)
(local.set $dividend_lo)
)
)
(if (i32.wrap_i64 (local.get $sign_divisor))
(then
(call $stdlib.sub-int128 (i64.const 0) (i64.const 0) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $divisor_hi)
(local.set $divisor_lo)
)
)
(call $stdlib.div-int128 (local.get $dividend_lo) (local.get $dividend_hi) (local.get $divisor_lo) (local.get $divisor_hi))
(local.set $remainder_hi)
(local.set $remainder_lo)
(local.set $quotient_hi)
(local.set $quotient_lo)
;; If the result should be negative, negate it
(if (i32.wrap_i64 (local.get $sign_dividend))
(then
(call $stdlib.sub-int128 (i64.const 0) (i64.const 0) (local.get $remainder_lo) (local.get $remainder_hi))
(local.set $remainder_hi)
(local.set $remainder_lo)
)
)
(return (local.get $remainder_lo) (local.get $remainder_hi))
)
(func $stdlib.lt-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.lt_u (local.get $a_lo) (local.get $b_lo))
(i64.lt_u (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.gt-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.gt_u (local.get $a_lo) (local.get $b_lo))
(i64.gt_u (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.le-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.le_u (local.get $a_lo) (local.get $b_lo))
(i64.le_u (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.ge-uint (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.ge_u (local.get $a_lo) (local.get $b_lo))
(i64.ge_u (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.lt-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.lt_u (local.get $a_lo) (local.get $b_lo))
(i64.lt_s (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.gt-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.gt_u (local.get $a_lo) (local.get $b_lo))
(i64.gt_s (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.le-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.le_u (local.get $a_lo) (local.get $b_lo))
(i64.le_s (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.ge-int (param $a_lo i64) (param $a_hi i64) (param $b_lo i64) (param $b_hi i64) (result i32)
(select
(i64.ge_u (local.get $a_lo) (local.get $b_lo))
(i64.ge_s (local.get $a_hi) (local.get $b_hi))
(i64.eq (local.get $a_hi) (local.get $b_hi))
)
)
(func $stdlib.lt-buff (param $offset_a i32) (param $length_a i32) (param $offset_b i32) (param $length_b i32) (result i32)
(local $i i32) (local $sub i32)
;; pseudo-code:
;; let i = min(length_a, length_b)
;; while i != 0 {
;; if ((sub = a[offset_a] - b[offset_b]) == 0) {
;; offset_a += 1; offset_b += 1; i -= 1;
;; } else { break }
;; }
;; return (sub != 0) ? (sub < 0) : (length_a < length_b)
(block $done
;; we can skip the comparison loop if $i (min length) is 0
(br_if $done
(i32.eqz
(local.tee $i
;; no i32.min in Wasm...
(select
(local.get $length_a)
(local.get $length_b)
(i32.lt_u (local.get $length_a) (local.get $length_b))
)
)
)
)
(loop $loop
(if
(i32.eqz
;; $sub will be 0 if both are equal, otherwise its sign indicates which is smaller
(local.tee $sub
(i32.sub (i32.load8_u (local.get $offset_a)) (i32.load8_u (local.get $offset_b)))
)
)
(then
(local.set $offset_a (i32.add (local.get $offset_a) (i32.const 1)))
(local.set $offset_b (i32.add (local.get $offset_b) (i32.const 1)))
(br_if $loop (local.tee $i (i32.sub (local.get $i) (i32.const 1))))
)