Fonction de base : Capteur temperature sans vérification

#include <OneWire.h>
#define DS18B20 0x28
#define BROCHE_ONEWIRE 7


OneWire ds(BROCHE_ONEWIRE);
byte adresseCapteur1 [8];   // Adresse du premier capteur


void getTemperature (float *temp, byte addr[])
{
    byte data[2];

    ds.reset();
    ds.select(addr);        // Sélectionne le capteur de température

    ds.write(0x44,1);       // Lance la mesure de température
    delay(800);
    
    ds.reset();             // Reset pour envoyer maintenant la demande de lecture
    ds.select(addr); 
    ds.write(0xBE);         // Demande de lecture du scratchpad

    data[0] = ds.read();    // Lit les 2 premiers octets du scratchpad sur lesquels est scontenue la température
    data[1] = ds.read();      
    *temp = ((data[1] << 8) | data[0]) * 0.0625;       // Conversion en degrés celsius
}


void setup() 
{
    Serial.begin(9600);     // Initialisation du port série

    ds.reset();
    ds.search(adresseCapteur1); // Recherche et stocke l'adresse du capteur 1
}


void loop () 
{
    float temp=20;

    getTemperature (&temp, adresseCapteur1);     // Demande la température

    Serial.print("Temperature : ");             // Affiche la température
    Serial.print(temp);
    Serial.write('°');
    Serial.write('C');
    Serial.println();

    delay (10000); // Attends 10 sec avant de recommencer
}