build.gradle

plugins {
    id 'java'
    id 'java-library'
    id 'maven-publish'
    id 'signing'
}

apply from: 'lib.gradle'

group = 'cn.vika'

java {
    withJavadocJar()
    withSourcesJar()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'vika-social'
            from components.java
            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
            pom {
                name = 'Vika Social Sdk'
                description = 'This is a project for vika SaaS'
                url = 'https://github.com/vikadata/vika-social'
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://vikadata.mit-license.org'
                    }
                }
                developers {
                    developer {
                        name = 'Bron'
                        email = 'liuzijing@vikadata.com'
                    }
                }
                scm {
                    connection = 'scm:git:git@github.com:vikadata/vika-social.git'
                    developerConnection = 'scm:git:git@github.com:vikadata/vika-social.git'
                    url = 'https://github.com/vikadata/vika-social'
                }
            }
        }
    }
    repositories {
        maven {
            name = "OSSRH"
            if (project.version.toString().endsWith("-SNAPSHOT")) {
                url = "https://oss.sonatype.org/content/repositories/snapshots"
            } else {
                url = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
            }
            credentials {
                username = System.getenv("MAVEN_USERNAME")
                password = System.getenv("MAVEN_PASSWORD")
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}


javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

allprojects {
    repositories {
        mavenCentral()
    }
}

jar {
    enabled = true
}