Ophthalmology - Add manual blinking and eye injuries

addons/ophthalmology/$PBOPREFIX$

@@ -0,0 +1 @@
+x\kat\addons\ophthalmology

addons/ophthalmology/ACE_Medical_Treatment_Actions.hpp

@@ -0,0 +1,26 @@
+class ACE_Medical_Treatment_Actions {
+    class Blink {
+        displayName = CSTRING(Blink_Display);
+        displayNameProgress = CSTRING(blink_action);
+        category = "bandage";
+        treatmentLocations = 0;
+        allowedSelections[] = {"Head"};
+        allowSelfTreatment = 1;
+        medicRequired = 0;
+        treatmentTime = 2;
+        items[] = {};
+        condition = QUOTE(missionNamespace getVariable [ARR_2(QQGVAR(enable),true)]);
+        callbackSuccess = QFUNC(treatmentAdvanced_blink);
+        callbackFailure = "";
+        callbackProgress = "";
+        consumeItem = 0;
+        animationPatient = "";
+        animationPatientUnconscious = "AinjPpneMstpSnonWrflDnon_rolltoback";
+        animationPatientUnconsciousExcludeOn[] = {"ainjppnemstpsnonwrfldnon"};
+        animationMedic = "AinvPknlMstpSlayWrflDnon_medicOther";
+        animationMedicProne = "AinvPpneMstpSlayW[wpn]Dnon_medicOther";
+        animationMedicSelf = "AinvPknlMstpSlayW[wpn]Dnon_medic";
+        animationMedicSelfProne = "AinvPpneMstpSlayW[wpn]Dnon_medic";
+        litter[] = {};
+    };
+};

addons/ophthalmology/CfgEventHandlers.hpp

@@ -0,0 +1,20 @@
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preInit));
+        disableModuload = "true";
+    };
+};
+
+class Extended_Init_EventHandlers {
+    class CAManBase {
+        class ADDON {
+            init = QUOTE([ARR_2((_this select 0), false)] call FUNC(init));
+        };
+    };
+};
+
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_postInit));
+    };
+};

addons/ophthalmology/XEH_PREP.hpp

@@ -0,0 +1,6 @@
+PREP(handleDustInjury);
+PREP(handleDustInjuryEffects);
+PREP(handleTime);
+PREP(init);
+PREP(initKeybinds);
+PREP(treatmentAdvanced_blink);

addons/ophthalmology/XEH_postInit.sqf

@@ -0,0 +1,34 @@
+#include "script_component.hpp"
+
+[QGVAR(handleTime), LINKFUNC(handleTime)] call CBA_fnc_addEventHandler;
+
+call FUNC(initKeybinds);
+
+// blur effect if not blinked
+GVAR(ppEffectPriority) = 341;
+[{
+    GVAR(ppEffectPriority) = GVAR(ppEffectPriority) + 1;
+    GVAR(ppBlur) = ppEffectCreate ["DynamicBlur", GVAR(ppEffectPriority)];
+    GVAR(ppBlur) != -1
+}, {
+    GVAR(ppBlur) ppEffectEnable false;
+}] call CBA_fnc_waitUntilAndExecute;
+
+// dust injury
+[{
+    GVAR(ppEffectPriority) = GVAR(ppEffectPriority) + 1;
+    GVAR(ppBlurDustInjury) = ppEffectCreate ["DynamicBlur", GVAR(ppEffectPriority)];
+    GVAR(ppBlurDustInjury) != -1
+}, {
+    GVAR(ppBlurDustInjury) ppEffectEnable false;
+}] call CBA_fnc_waitUntilAndExecute;
+
+// blink effect
+GVAR(ppEffectPriority) = 1111;
+[{
+    GVAR(ppEffectPriority) = GVAR(ppEffectPriority) + 1;
+    GVAR(ppBlurBlink) = ppEffectCreate ["DynamicBlur", GVAR(ppEffectPriority)];
+    GVAR(ppBlurBlink) != -1
+}, {
+    GVAR(ppBlurBlink) ppEffectEnable false;
+}] call CBA_fnc_waitUntilAndExecute;

addons/ophthalmology/XEH_preInit.sqf

@@ -0,0 +1,91 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+PREP_RECOMPILE_START;
+#include "XEH_PREP.hpp"
+PREP_RECOMPILE_END;
+
+#define CBA_SETTINGS_CAT "KAT - ADV Medical: Ophthalmology"
+
+// Enable Dust Injury
+[
+    QGVAR(enable),
+    "CHECKBOX",
+    LLSTRING(SETTING_ENABLE),
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Injury)],
+    [true],
+    true
+] call CBA_Settings_fnc_init;
+
+// Probability to get dust in the eyes
+[
+    QGVAR(probability_dust),
+    "SLIDER",
+    [LLSTRING(SETTING_BLINK_EFFECT_INTENSITY)],
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Injury)],
+    [1, 100, 5, 0],
+    true
+] call CBA_Settings_fnc_init;
+
+// Probability to get dust in the eyes which is not treated by blink
+[
+    QGVAR(probability_dust_heavy),
+    "SLIDER",
+    [LLSTRING(SETTING_BLINK_EFFECT_INTENSITY)],
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Injury)],
+    [1, 100, 1, 0],
+    true
+] call CBA_Settings_fnc_init;
+
+// Probability to treat the dust in the eyes with blinking
+[
+    QGVAR(probability_treatment_dust),
+    "SLIDER",
+    [LLSTRING(SETTING_BLINK_EFFECT_INTENSITY)],
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Injury)],
+    [1, 100, 20, 0],
+    true
+] call CBA_Settings_fnc_init;
+
+// Dust in the eye post process effect intensity
+[
+    QGVAR(dust_effect_intensity),
+    "SLIDER",
+    [LLSTRING(SETTING_DUST_EFFECT_INTENSITY)],
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Injury)],
+    [1, 10, 3, 0],
+    true
+] call CBA_Settings_fnc_init;
+
+// Enable manual blinking
+[
+    QGVAR(enableManualBlinking),
+    "CHECKBOX",
+    LLSTRING(SETTING_ENABLE_MANUAL_BLINKING),
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Manual)],
+    [false],
+    true
+] call CBA_Settings_fnc_init;
+
+// Time span blinking is needed
+[
+    QGVAR(blink_duration),
+    "SLIDER",
+    [LLSTRING(SETTING_BLINK_DURATION)],
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Manual)],
+    [1, 600, 60, 0],
+    true
+] call CBA_Settings_fnc_init;
+
+// Blinking post process effect intensity
+[
+    QGVAR(blink_effect_intensity),
+    "SLIDER",
+    [LLSTRING(SETTING_BLINK_EFFECT_INTENSITY)],
+    [CBA_SETTINGS_CAT, LSTRING(SETTING_SubCategory_Manual)],
+    [1, 10, 5, 0],
+    true
+] call CBA_Settings_fnc_init;
+
+ADDON = true;

addons/ophthalmology/config.cpp

@@ -0,0 +1,22 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON    {
+        name = COMPONENT_NAME;
+        requiredVersion = REQUIRED_VERSION;
+        units[] = {};
+        weapons[] = {};
+        magazines[] = { };
+        requiredAddons[] = {
+            "kat_main",
+            "cba_settings"
+        };
+        author = "Katalam";
+        authors[] = {"Katalam"};
+        url = ECSTRING(main,URL);
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "ACE_Medical_Treatment_Actions.hpp"

addons/ophthalmology/functions/fnc_handleDustInjury.sqf

@@ -0,0 +1,43 @@
+#include "script_component.hpp"
+/*
+ * Author: Katalam
+ * Handles the possibility to have dust in the eye.
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+ */
+
+params ["_player", "_pfhID"];
+
+if !(GVAR(enable)) exitWith {};
+
+// check headgear and googles for protection
+private _safe = false;
+
+if (headgear _unit != "") then {
+    _safe = getNumber (configFile >> "CfgWeapons" >> headgear _unit >> "ACE_Protection") == 1;
+};
+
+// if the headgear is not enough to protect, we check the goggles
+if (!_safe) then {
+    _safe = _player call ACEFUNC(goggles,isGogglesVisible);
+};
+
+// if protected, do nothing
+if (_safe) exitWith {};
+
+
+// get a random integer
+private _random = floor(random [0, 50, 100]);
+
+// we only need to set the variables
+// pp effect will be added through extra pfh
+if (_random <= GVAR(probability_dust_heavy)) exitWith {
+    _player setVariable [QGVAR(dust_injury_heavy), true, true];
+};
+
+if (_random <= GVAR(probability_dust)) exitWith {
+    _player setVariable [QGVAR(dust_injury), true, true];
+};

addons/ophthalmology/functions/fnc_handleDustInjuryEffects.sqf

@@ -0,0 +1,27 @@
+#include "script_component.hpp"
+/*
+ * Author: Katalam
+ * Handles the effects of having dust in the eyes.
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+ */
+
+params ["_player", "_pfhID"];
+
+if !(GVAR(enable)) exitWith {};
+
+private _dustInjury = _player getVariable [QGVAR(dust_injury), false];
+private _dustInjuryHeavy = _player getVariable [QGVAR(dust_injury_heavy), false];
+
+// no injuries?
+if (!_dustInjury && !_dustInjuryHeavy) exitWith {};
+
+// already enabled?
+if (ppEffectEnabled GVAR(ppBlurDustInjury)) exitWith {};
+
+GVAR(ppBlurDustInjury) ppEffectEnable true;
+GVAR(ppBlurDustInjury) ppEffectAdjust [GVAR(dust_effect_intensity)];
+GVAR(ppBlurDustInjury) ppEffectCommit 30;

addons/ophthalmology/functions/fnc_handleTime.sqf

@@ -0,0 +1,23 @@
+#include "script_component.hpp"
+/*
+ * Author: Katalam
+ * Handles the current moment if blinking was needed in the past
+ * and ands pp effects if needed
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+ */
+
+params ["_player", "_pfhID"];
+
+if !(GVAR(enableManualBlinking)) exitWith {};
+
+private _lastBlink = _player getVariable [QGVAR(lastBlink), 0];
+
+if (CBA_missionTime > _lastBlink + GVAR(blink_duration)) then {
+    GVAR(ppBlur) ppEffectEnable true;
+    GVAR(ppBlur) ppEffectAdjust [GVAR(blink_effect_intensity)];
+    GVAR(ppBlur) ppEffectCommit GVAR(blink_duration);
+};

addons/ophthalmology/functions/fnc_init.sqf

@@ -0,0 +1,23 @@
+#include "script_component.hpp"
+/*
+ * Author: Katalam
+ * Will initialize the frame handler for the manual blinking and dust injuries
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+ */
+
+params ["_unit", ["_isRespawn", true]];
+
+if (!local _unit) exitWith {};
+
+if (GVAR(enable)) then {
+    [FUNC(handleDustInjury), 60, _unit] call CBA_fnc_addPerFrameHandler;
+    [FUNC(handleDustInjuryEffects), 1, _unit] call CBA_fnc_addPerFrameHandler;
+};
+
+if (GVAR(enableManualBlinking)) then {	
+    [FUNC(handleTime), 1, _unit] call CBA_fnc_addPerFrameHandler;
+};

addons/ophthalmology/functions/fnc_initKeybinds.sqf

@@ -0,0 +1,35 @@
+#include "script_component.hpp"
+#include "\a3\ui_f\hpp\defineDIKCodes.inc"
+/*
+ * Author: Katalam
+ * Initialize the keybinds.
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+ *
+ * https://community.bistudio.com/wiki/DIK_KeyCodes
+ */
+
+if (!hasInterface) exitWith {};
+
+[QUOTE(COMPONENT_BEAUTIFIED), QGVAR(blinking), LLSTRING(blinking),
+{
+    ACE_PLAYER setVariable [QGVAR(lastBlink), CBA_missionTime];
+    GVAR(ppBlur) ppEffectEnable false;
+    GVAR(ppBlur) ppEffectAdjust [0];
+    GVAR(ppBlur) ppEffectCommit 0;
+
+    GVAR(ppBlurBlink) ppEffectEnable true;
+    GVAR(ppBlurBlink) ppEffectAdjust [0.5];
+    GVAR(ppBlurBlink) ppEffectCommit 0.5;
+
+    [{
+        GVAR(ppBlurBlink) ppEffectEnable false;
+        GVAR(ppBlurBlink) ppEffectAdjust [0];
+        GVAR(ppBlurBlink) ppEffectCommit 0.5;
+    }, [], 0.1] call CBA_fnc_waitAndExecute;
+}, "",
+[DIK_TAB, [false, false, false]], false] call CBA_fnc_addKeybind;
+// [DIK, [shift, ctrl, alt]] 

addons/ophthalmology/functions/fnc_treatmentAdvanced_blink.sqf

@@ -0,0 +1,32 @@
+#include "script_component.hpp"
+/*
+ * Author: Katalam
+ * Handles the possibility to treat dust in the eye with blinking
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+ *
+ */
+
+params ["_medic", "_patient"];
+
+// get a random integer
+private _random = floor(random [0, 50, 100]);
+
+// heavy dust injury?
+if (_patient getVariable [QGVAR(dust_injury_heavy), false]) exitWith {};
+// no dust injury?
+if !(_patient getVariable [QGVAR(dust_injury), false]) exitWith {};
+
+if (_random <= GVAR(probability_treatment_dust)) then {
+    _patient setVariable [QGVAR(dust_injury), false, true];
+    GVAR(ppBlurDustInjury) ppEffectEnable false;
+    GVAR(ppBlurDustInjury) ppEffectAdjust [0];
+    GVAR(ppBlurDustInjury) ppEffectCommit 0;
+
+    true;
+};
+
+false;

addons/ophthalmology/functions/script_component.hpp

@@ -0,0 +1 @@
+#include "\x\kat\addons\ophthalmology\script_component.hpp"