Add "other tab" actions to some commands

* ivy.el (ivy--switch-buffer-other-tab-action): New action function.
(ivy-switch-buffer):
* counsel.el (counsel-find-file, counsel-recentf)
(counsel-buffer-or-recentf, counsel-bookmark)
(counsel-switch-buffer): New action function
(counsel--bookmark-jump-other-tab). Add "other tab" actions, but only
on the condition that the relevant features are available (because Ivy
supports Emacsen before they were introduced) (#2915).

counsel.el

@@ -1935,8 +1935,10 @@ choose between `yes-or-no-p' and `y-or-n-p'; otherwise default to
 
 (ivy-set-actions
  'counsel-find-file
- '(("j" find-file-other-window "other window")
+ `(("j" find-file-other-window "other window")
    ("f" find-file-other-frame "other frame")
+   ,@(and (fboundp 'find-file-other-tab)
+          '(("t" find-file-other-tab "other tab")))
    ("b" counsel-find-file-cd-bookmark-action "cd bookmark")
    ("x" counsel-find-file-extern "open externally")
    ("r" counsel-find-file-as-root "open as root")
@@ -2331,6 +2333,8 @@ https://www.freedesktop.org/wiki/Specifications/desktop-bookmark-spec"))
  'counsel-recentf
  `(("j" find-file-other-window "other window")
    ("f" find-file-other-frame "other frame")
+   ,@(and (fboundp 'find-file-other-tab)
+          '(("t" find-file-other-tab "other tab")))
    ("x" counsel-find-file-extern "open externally")
    ("d" ,(lambda (file) (setq recentf-list (delete file recentf-list)))
     "delete from recentf")))
@@ -2439,8 +2443,10 @@ This function uses the `dom' library from Emacs 25.1 or later."
 
 (ivy-set-actions
  'counsel-buffer-or-recentf
- '(("j" find-file-other-window "other window")
+ `(("j" find-file-other-window "other window")
    ("f" find-file-other-frame "other frame")
+   ,@(and (fboundp 'find-file-other-tab)
+          '(("t" find-file-other-tab "other tab")))
    ("x" counsel-find-file-extern "open externally")))
 
 (defun counsel-buffer-or-recentf-transformer (var)
@@ -2488,9 +2494,15 @@ By default `counsel-bookmark' opens a dired buffer for directories."
   (lambda (bookmark)
     (funcall fn (bookmark-location bookmark))))
 
+(defun counsel--bookmark-jump-other-tab (bookmark)
+  "Jump to BOOKMARK in another tab."
+  (bookmark-jump bookmark 'switch-to-buffer-other-tab))
+
 (ivy-set-actions
  'counsel-bookmark
  `(("j" bookmark-jump-other-window "other window")
+   ,@(and (fboundp 'switch-to-buffer-other-tab)
+          `(("t" counsel--bookmark-jump-other-tab "other tab")))
    ("d" bookmark-delete "delete")
    ("e" bookmark-rename "edit")
    ("s" bookmark-set "overwrite")
@@ -6346,8 +6358,10 @@ in the current window."
 
 (ivy-set-actions
  'counsel-switch-buffer
- '(("x" counsel-open-buffer-file-externally "open externally")
-   ("j" ivy--switch-buffer-other-window-action "other window")))
+ `(("x" counsel-open-buffer-file-externally "open externally")
+   ("j" ivy--switch-buffer-other-window-action "other window")
+   ,@(and (fboundp 'find-file-other-tab)
+          '(("t" ivy--switch-buffer-other-tab-action "other tab")))))
 
 ;;** `counsel-compile'
 (defvar counsel-compile-history nil

ivy.el

@@ -4441,6 +4441,17 @@ BUFFER may be a string or nil."
           (find-file-other-window (cdr virtual))
         (switch-to-buffer-other-window buffer)))))
 
+(defun ivy--switch-buffer-other-tab-action (buffer)
+  "Switch to BUFFER in other tab.
+BUFFER may be a string or nil."
+  (if (zerop (length buffer))
+      (switch-to-buffer-other-tab ivy-text)
+    (let ((virtual (assoc buffer ivy--virtual-buffers)))
+      (if (and virtual
+               (not (get-buffer buffer)))
+          (find-file-other-tab (cdr virtual))
+        (switch-to-buffer-other-tab buffer)))))
+
 (defun ivy--rename-buffer-action (buffer)
   "Rename BUFFER."
   (let ((new-name (read-string "Rename buffer (to new name): ")))
@@ -4505,12 +4516,16 @@ Otherwise, forward to `ivy-kill-line'."
 
 (ivy-set-actions
  'ivy-switch-buffer
- '(("f"
+ `(("f"
     ivy--find-file-action
     "find file")
    ("j"
     ivy--switch-buffer-other-window-action
     "other window")
+   ,@(and (fboundp 'find-file-other-tab)
+          '(("t"
+             ivy--switch-buffer-other-tab-action
+             "other tab")))
    ("k"
     ivy--kill-buffer-action
     "kill")