Use buildSrc to organize project structure

buildSrc/build.gradle.kts

@@ -0,0 +1,14 @@
+plugins {
+    `kotlin-dsl`
+}
+
+group = "dev.shiza"
+version = "1.0.0-SNAPSHOT"
+
+repositories {
+    gradlePluginPortal()
+}
+
+dependencies {
+    implementation(kotlin("script-runtime"))
+}

buildSrc/src/main/kotlin/dew-java.gradle.kts

@@ -0,0 +1,20 @@
+plugins {
+    `java-library`
+}
+
+java {
+    toolchain {
+        languageVersion = JavaLanguageVersion.of(17)
+    }
+}
+
+sourceSets {
+    main {
+        java.setSrcDirs(listOf("src"))
+        resources.setSrcDirs(emptyList<String>())
+    }
+    test {
+        java.setSrcDirs(emptyList<String>())
+        resources.setSrcDirs(emptyList<String>())
+    }
+}

buildSrc/src/main/kotlin/dew-publish.gradle.kts

@@ -0,0 +1,34 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+group = "dev.shiza"
+version = "1.0.0-SNAPSHOT"
+
+java {
+    withSourcesJar()
+}
+
+publishing {
+    repositories {
+        mavenLocal()
+    }
+}
+
+interface DewPublishExtension {
+    var artifactId: String
+}
+
+val extension = extensions.create<DewPublishExtension>("dewPublish")
+
+afterEvaluate {
+    publishing {
+        publications {
+            create<MavenPublication>("maven") {
+                artifactId = extension.artifactId
+                from(project.components["java"])
+            }
+        }
+    }
+}

buildSrc/src/main/kotlin/dew-repositories.gradle.kts

@@ -0,0 +1,7 @@
+plugins {
+    `java-library`
+}
+
+repositories {
+    mavenCentral()
+}

dew-common/build.gradle.kts

@@ -0,0 +1,12 @@
+plugins {
+    `dew-java`
+    `dew-publish`
+    `dew-repositories`
+}
+
+group = "dev.shiza"
+version = "1.0.0-SNAPSHOT"
+
+dewPublish {
+    artifactId = "dew"
+}

gradle.properties

@@ -0,0 +1,9 @@
+#not handy tbh
+#org.gradle.vfs.watch=true
+org.gradle.parallel=true
+org.gradle.daemon=true
+org.gradle.caching=true
+org.gradle.jvmargs=-Xmx2048M
+#wait for https://github.com/gradle/gradle/issues/24040
+#org.gradle.unsafe.configuration-cache=true
+kotlin.stdlib.default.dependency=false

settings.gradle.kts

@@ -1,2 +1,2 @@
 rootProject.name = "dew"
-
+include(":dew-common")