Setup dev dependencies using nix flakes and devenv.sh

See https://devenv.sh/ and https://github.com/direnv/direnv.

Start your development environment by copying .envrc.example to .envrc
and use `direnv allow` to enable.

After the build completes (it is cached) you can run `devenv up` to
start PostgreSQL on port 6543. Use `devenv test` to create the
databases and run the tests.

.envrc.example

@@ -0,0 +1,5 @@
+# Use Nix to setup development dependencies, github hooks, and services with `devenv`.
+# See `flake.nix` for the setup.
+watch_file flake.nix
+watch_file flake.lock
+use flake . --no-pure-eval

.gitignore

@@ -7,3 +7,6 @@ tmp/*
 .vscode
 integration-specs/rails-app/Gemfile.lock
 integration-specs/simple/Gemfile.lock
+.envrc
+.devenv
+/.pre-commit-config.yaml

flake.nix

@@ -0,0 +1,85 @@
+{
+  inputs = {
+    nixpkgs.url = "github:cachix/devenv-nixpkgs/rolling";
+    systems.url = "github:nix-systems/default";
+    devenv.url = "github:cachix/devenv";
+    devenv.inputs.nixpkgs.follows = "nixpkgs";
+  };
+
+  nixConfig = {
+    extra-trusted-public-keys = "devenv.cachix.org-1:w1cLUi8dv3hnoSPGAuibQv+f9TZLr6cv/Hm9XgU50cw=";
+    extra-substituters = "https://devenv.cachix.org";
+  };
+
+  outputs = { self, nixpkgs, devenv, systems, ... } @ inputs:
+    let
+      forEachSystem = nixpkgs.lib.genAttrs (import systems);
+    in
+    {
+      packages = forEachSystem (system: {
+        devenv-up = self.devShells.${system}.default.config.procfileScript;
+        devenv-test = self.devShells.${system}.default.config.test;
+      });
+
+      devShells = forEachSystem
+        (system:
+          let
+            postgresPort = 6543;
+            pkgs = nixpkgs.legacyPackages.${system};
+          in
+          {
+            default = devenv.lib.mkShell {
+              inherit inputs pkgs;
+              modules = [
+                {
+                  env.PGPORT = postgresPort;
+
+                  enterTest = ''
+                    reset-database
+                    run-tests
+                  '';
+
+                  git-hooks.hooks.rubocop = {
+                    enable = true;
+                    name = "rubocop";
+                    types = [ "ruby" ];
+                    excludes = [
+                      "^docs/.*$"
+                      "^integration-specs/rails-app/(bin|db)/.*$"
+                      "^integration-specs/rails-app/config/puma.rb$"
+                    ];
+                    entry = "bundle exec rubocop";
+                  };
+
+                  languages.ruby = {
+                    enable = true;
+                    package = pkgs.ruby;
+                  };
+
+                  services.postgres = {
+                    enable = true;
+                    listen_addresses = "127.0.0.1";
+                    port = postgresPort;
+                    initialScript = ''
+                      CREATE ROLE sequent LOGIN SUPERUSER;
+                    '';
+                    settings = {
+                      log_min_duration_statement = "100ms";
+                    };
+                  };
+
+                  # https://devenv.sh/reference/options/
+                  packages = with pkgs; [
+                    libyaml
+                    pkg-config
+                    postgresql
+                  ];
+
+                  scripts.run-tests.exec = "bundle exec rspec";
+                  scripts.reset-database.exec = "SEQUENT_ENV=test bundle exec rake sequent:db:drop sequent:db:create";
+                }
+              ];
+            };
+          });
+    };
+}